[Closed] When object deleted, delete children. Huh?

Okay, well, I tried linking the various nodes from the tabs to each other instead of to the master, and there were no problems with undo. So can we just create a something to hold the nodeTab array without actually having anything parented to it, and tell it if the parent node is deleted to delete the rest?

Or, do you already have something in mind besides using nodeTab?

What about my other suggestion? Not worth looking into? x)

create a something to hold the nodeTab array without actually having anything parented to it, and tell it if the parent node is deleted to delete the rest?

In other words, have one node that is the parent to to the others, and one that holds them all in a nodeTab.

edit: deleted as doubled

what? the post is doubled. never mind. read the last one

I have no problem reading the help. Part of the reason I brought it up, though, is that I thought doing it the other way would help me more with my other goal, which is to set something up where if ANY of the objects in a collection like this are deleted, then all of the rest will ALSO be deleted.

that’s the simplest part in the our (technically yours) pipeline. the only thing we need is to receive right messages. that’s the thing that we are working on now.
PS: (probably you guess that i have already a completely working solution, but it’s so boring just post it)

I’m sure it’s a lot more fun to watch me flail helplessly.

I promise, I am trying to learn here. Anyway, just swapping things in like this obviously doesn’t work:

global containerAttrib = attributes containerAttrib attribID:#(0x1f05aab6, 0x7a59c3a6)
(
	local handler
	fn constructNode =
	(
		--format "theHold.redoing(): %, theHold.holding(): %
" (theHold.redoing()) (theHold.holding())
		if not (theHold.redoing() or theHold.holding()) do
		(
			node = refs.dependentNodes (custAttributes.getOwner this) firstOnly:on
			if (isValidNode node) and not (isDeleted node) and (handler == undefined) do
			(
				handler =	when node deleted node do
				(
				    if (attr = nodeTransformMonitor node:node) != undefined do
					(
						if attr.handler != undefined do deleteChangeHandler attr.handler
						attr.handler = undefined
						delete (for n in attr.container where isValidNode n and not isDeleted n collect n)
						attr.container = #()
					)
				) -- end handler
			)
		)
	) -- end fn constructNode
	parameters params 
	(
		container type:#maxObjectTab tabSizeVariable:on
		on container set val do constructNode()
	)
	on update do constructNode()
	on load do constructNode()
)

And I don’t know what to do instead because there’s nothing useful in the documentation about working with node transform monitors.

I have a question: Why we need to use for loop with n=[1,1,10] and declare master dummy as global. Can we simply use this concept?

global ContainerAttrib = attributes ContainerAttrib attribID:#(0x1f05aab6, 0x7a59c3a6)
(
	local handler
	fn getNode = (refs.dependentnodes (custattributes.getowner this) firstonly:on)
	fn constructNode node: = if not (theHold.Redoing() or theHold.Holding()) do
	(
		if node == unsupplied do node = getNode()
		if isvalidnode node and not isdeleted node and handler == undefined do
		(
			handler = when node deleted node do if (attr = node.baseobject.custattributes[#ContainerAttrib]) != undefined do 
			(
				if attr.handler != undefined do deleteChangeHandler attr.handler
				attr.handler = undefined
				delete (for n in attr.container where isvalidnode n.node and not isdeleted n.node collect n.node)
				attr.container = #()
			)
		)
	)
	parameters params 
	(
		container type:#maxObjectTab tabsizevariable:on
		on container set val do constructNode()
	)

	on update do constructNode()
	on load do constructNode()
)
(
	gc() ; delete objects
	dm = dummy name:(uniquename "master") pos:[0,0,0]
	custattributes.add dm ContainerAttrib
	dm.ContainerAttrib.constructNode()
	dm.container = for k = 1 to 10 collect (nodeTransformMonitor node:(point pos:[k*20,0,0] wirecolor:orange parent:dm) forwardTransformChangeMsgs:false)
	print "DONE!" ; ok
)

global ContainerAttrib = attributes ContainerAttrib attribID:#(0x1f05aab6, 0x7a59c3a6)
(
	local handler
	fn getNode = (refs.dependentnodes (custattributes.getowner this) firstonly:on)
	fn constructNode node: = if not (theHold.Redoing() or theHold.Holding()) do
	(
		if node == unsupplied do node = getNode()
		if isvalidnode node and not isdeleted node and handler == undefined do
		(
			handler = when node deleted node do if (attr = node.baseobject.custattributes[#ContainerAttrib]) != undefined do 
			(
				if attr.handler != undefined do deleteChangeHandler attr.handler
				attr.handler = undefined
				delete (for n in attr.container where isvalidnode n and not isdeleted n collect n)
				--delete (for n in attr.container where iskindof n NodeTransformMonitor and isvalidnode n.node and not isdeleted n.node collect n.node)
				attr.container = #()
			)
		)
	)
	parameters params 
	(
		container type:#nodeTab tabsizevariable:on
--		container type:#maxobjectTab tabsizevariable:on
		on container set val do constructNode()
	)

	fn constructTransform = 
	(
		when parameters container change handleAt:#redrawViews do format "params changed...
"
	)
	on create do constructTransform()

	on update do constructNode()
	on load do constructNode()
)
(
	num = [1,2,4]
	for i=1 to num[1] do 
	(
		gc()
		delete objects
		for k=1 to num[2] do
		(
			y = (k-1)*20
			global b = dummy name:(uniquename "master") pos:[0,y,0]
			custattributes.add b ContainerAttrib
			b.container = for k = 1 to num[3] collect (point pos:[k*20,y,0] wirecolor:orange)
			--in b (b.container = for k = 1 to num[3] collect NodeTransformMonitor node:(point pos:[k*20,y,0] wirecolor:orange))
		)
	)
	print "DONE!"
	ok
)

i returned the code to the nodeTab solution. as you can see any move, link, delete, etc… actions with point fires a parameter changed event (because we constructed it using when parameters container change).
now change the code to the maxobjectTab and NodeTransformMonitor solution. and you will see that our when construct stops working. that’s because NodeTransformMonitor doesn’t notify its dependents about all events.