ok…
here is a regex solution. the most complicated part was to write the right expression.

 fn makeBoneRegex charname: bonename: type:#any = 
 (
 	if charname == unsupplied do charname = ".*" 
 	if bonename == unsupplied do bonename = ".*" 
 	type = case type of
 	(
 		  #any: "[l,m,r]"
 		#right: "r"
 		 #left: "l"
 	   #middle: "m"
 	   default: "[a-z]" 
 	)
 	dotnetobject "System.Text.RegularExpressions.Regex" ("(^" + charname + "_?)(" + bonename + ")([0-9]{3}?)(_" + type + "_)([0-9]{1,}$)")
 )
 
 struct BoneStruct (node, char, name, index, type, id)
 fn getBones nodes: charname: bonename: type:#any = 
 (
 	if nodes == unsupplied do nodes = objects as array
 		
 	rg = makeBoneRegex charname:charname bonename:bonename type:type
 	for node in nodes where rg.IsMatch node.name collect 
 	(
 		d = (rg.Match node.name).groups
 		BoneStruct node:node \
 			char:(trimright d.item[1].value "_") \
 			name:d.item[2].value \
 			index:(d.item[3].value as integer) \
 			type:d.item[4].value[2] \
 			id:(d.item[5].value as integer)
 	)
 )
 /*
 (
 	delete objects
 	local chars = #("Chip", "Dale", "Jack")
 	local bones = #("arm", "leg", "spine")
 	local types = #("l", "m", "r")
 	
 	seed 0
 	for k=1 to 100 do 
 	(
 		name = chars[random 1 3] + "_" + bones[random 1 3] + (formattedprint (random 1 6) format:"03d") + "_" + types[random 1 3] + "_"
 		box name:(uniquename name)
 	)
 )
 -- print all chip's right arms
 print (getBones charname:"Chip" bonename:"arm" type:#right)
 -- print all dale's bones
 print (getBones charname:"Dale") 
 */
 

when we found all bones that matches the pattern it’s easy to sort them by index and find the highest. after that there’s no problem to make the unique name

While developing this and messing around with different ideas of my own that was something i was trying to grasp and understand as well. Meaning the best way to right a solution that would work well. I was unable to come up with a solid solution myself. I did begin reading up on the regex stuff once you mentioned it. I was un aware of what that brings to maxscript. It’s useful to know that is available. I’ll check out what you’ve written here. I’m excited to get this working and implemented. I appreciate the time you spent working on this Denis. I’ll let you know how it goes.

So I’m not entirely sure how to use what is written here.

Say i run what you’ve written and uncomment the loop which creates boxes.

ok so now I want to create an additional box but with a unique name. Where does that happen?

Do i increment the index?

you got all bones as structure

find item with maximum index (let’s call it b)

make new(unique) name as:

uniquename (b.char + "_" + b.name + (formattedprint (b.index+1) format:"03d") + "_" + b.type + "_")

that’s it

so I did something like this

 	exBones = (getBones charname:"Dale" bonename:"leg")
	b = exBones[exBones.count]
	newPt = point name:(uniquename (b.char + "_" + b.name + (formattedprint (b.index+1) format:"03d") + "_" + b.type + "_"))

for bug sake purposes it bugs out if no bone exists. using the code i pasted above.

This is great. I’ve got it working. Thanks Denis
It took a little understanding and then it all came together.