[Closed] supersampling materials

The global setting is active by default.
I presume It is the source of the error?

boxmaterial.samplerUseGlobal = false
boxmaterial.samplerEnable = true

Yes, thanks, that was this omission.
Now i’ll try to complete the script.
‘Hope i won’t need more help.

thanks again

Ok i did it

if someone is intersted, here is the basic script :

on execute do (

sel = selection
for i in sel do (
g = i.material
g.samplerUseGlobal = false
g.samplerEnable = true )
)

It should be tuned to check, for example, for empty selection or invalid selection and it will be.

hope this helps

Again me, with another question (eventualy, i need help isn’t it ?).

I would like to filter the selection. I know already how to do it, but i’m sure there’s a faster and more “elegant” way to do it. Basically, i would like to write something like this :

sel = selection
for i in sel where i iskindof geometry do (…)

but it doesn’t work

Does someone know a trick ?

The solution is not far.
But the class and the order of the arguments are wrong:

for obj in selection where iskindof obj geometryClass do (format "object=%
" obj)

And It is the same that to say:

for obj in geometry do (format "object=%
" obj)

Have a good day

Thank you again

I’ll try it.

Did it,

Here is the code if someone is interested

(on execute do
(

sel = selection
for obj in sel where iskindof obj geometryClass do
(
g = obj.material
if classof g == multimaterial then
(for i in g.count to 1 by -1 do
(g[i].sampleruseglobal = false
g[i].samplerenable = true
g[i].samplerbyname = “Max 2.5 Star”)
)
else(
h = obj.material
h.samplerUseGlobal = false
h.samplerEnable = true
h.samplerbyname = “Max 2.5 Star”
)
)
)
)

For now, it handles only standard, architectural (perhaps some other mat ?) and multimaterial. I will tune it, with a case of: loop for all materials supporting supersampling.

Thanks again for helping

I’m coming again to ask for help.

Now, my script works well. It can handles almost all kind of Max standard material, but i realise it will be much more difficult to finish it that i first expected.
The problem is that this script works only with the first nested level of material.

Lets be more specific :

for example, if an object has a multimaterial, or a composite, or a blend (etc…) applied to it, the script will enable the supersampling for the standard material used in the this material material. But what if a multimaterial has another multimaterial has a submaterial (getting confused isn’t it ,) ? My script is unable to handle these situations. It doesn’t crash because i catch the error message, but the submaterials aren’t supersampled.

So here is my question :

Does it exist a “simple” way to check for all nested materials of an object and -first- determine if they could be supersampled and -then- enable the supesampling for these materials ?

Here is my code for now:

on button1 pressed do
(sel = selection
for obj in sel where iskindof obj geometryClass do
(case of
(
(d = obj.material
classof d == blend):
(try (d.map1.sampleruseglobal = false
d.map1.samplerenable = true
d.map1.samplerbyname = “Max 2.5 Star”
d.map2.sampleruseglobal = false
d.map2.samplerenable = true
d.map2.samplerbyname = “Max 2.5 Star”
)
catch ()
)

			(f = obj.material
			 classof f == compositematerial):
				(try (e = f.materiallist
				 		for i in e.count to 1 by -1 where e[i] != undefined do
					 		(e[i].sampleruseglobal = false
			 	 	 	 	e[i].samplerenable = true
				 	 	 	e[i].samplerbyname = "Max 2.5 Star"
					    	)
					  )
				 catch ()
			    )

			(g = obj.material
			 classof g == multimaterial):
				(try (for i in g.count to 1 by -1 do
					 	(g[i].sampleruseglobal = false
			 	 	 	 g[i].samplerenable = true
				 	 	 g[i].samplerbyname = "Max 2.5 Star"
					    )
					  )
				  catch ()
				 )
	
			default:
				(try (g = obj.material
			     	  g.samplerUseGlobal = false
				 	  g.samplerEnable = true
				 	  g.samplerbyname = "Max 2.5 Star"
					 )
				 catch ()
				)
		)
 	)	
)

Thanks for help

No offense, but your code is unreadable :o) Add spaces help to understand a code and It does not slow down the program…

The solution is to use an recursive function.

utility setSamplerRollout "setSampler"
(
button setSampler_osd "setSampler"

fn setSampler mat =
(
	case classof mat of
	(
		blend: (setSampler mat.map1; setSampler mat.map2)
		compositematerial: (for thisMat in mat.materiallist where thisMat!=undefined do setSampler thisMat)
		multimaterial: (for thisMat in mat.materiallist where thisMat!=undefined do setSampler thisMat)
		standardmaterial:
		(
			mat.samplerUseGlobal = false
			mat.samplerEnable = true
			mat.samplerbyname = "Max 2.5 Star"
		)
	)--case
)--fn

on setSampler_osd pressed do
(
	matSel=#()
	for obj in selection where isKindOf obj GeometryClass do
	(
		mat=obj.material
		if mat!=undefined do ( if findItem matSel mat==0 then append matSel mat )
	)
	for mat in matSel do setSampler mat
)--on

)--utility