[Closed] Storing nodes in a Dropdownlist

MAXScript is right

objrem = for i in ch01lst.selection collect ch01lst.items[i]

In this case, ch01lst.selection is the index of the currently selected object, an integer. You cannot map on integers, only on arrays and collections. Since this is a dropdownlist and not a multilistbox, only one object can be selected at a time.

The property .selected returns the name of the item currently selected.
So you could say

objrem = getNodeByName ch01lst.selected
if isValidNode objrem do
(
– … perform the disconnection operations on the node here.
)

Regardless of whether the node could be found or not (it could have been deleted from the scene and the list would not know it!), you would delete the item from the list.

That worked beautifully, thank you.

However, I still have a problem: that being the fact that when I deselect and reselect the object that this modifier script is on, it no longer displays the items in the dropdownlist. How can I keep it from resetting?

YES! and it worked very well.
For a minute I got it to store the data, but not show the list each time you select the item, but I got it fixed.

Okay, here is my complete script:

--
-- FoaS Aquaruis Zodiac-series Dimmer Rack
-- Version 0.1a
-- 
-- (C) Robert Mayer 2k6-Infinity

-- Description: A modifier used to link the console to the scene.

plugin modifier AquDimmer
name:"FoaS Aquarius Dimmer"
classID:#(0x60418e0d, 0x5d3eefb6)
(
parameters main rollout:dimmer
	(
	--start parameters
	
	--Guide
	-- ch00d = intensity
	-- ch00c = color
	-- ch00h = hotspot
	-- ch00f = falloff
	
	--UI Guide
	--sld = slider
	--spn = spinner
	--pkr = colorpicker

	--Channel 01
	ch01d		type:#float		default:1
	ch01c		type:#color		default:(color 255 255 255)
	ch01h		type:#float		default:30
	ch01f		type:#float		default:45
	ch01cnt		type:#stringtab	tabsizeVariable:true
	
	--Channel 02
	ch02d		type:#float		default:1
	ch02c		type:#color		default:(color 255 255 255)
	ch02h		type:#float		default:30
	ch02f		type:#float		default:45
	
	--Channel 03
	ch03d		type:#float		default:1
	ch03c		type:#color		default:(color 255 255 255)
	ch03h		type:#angle		default:30
	ch03f		type:#angle		default:45
	
	--end parameters
	)

--Rollout

Rollout dimmer "Aquarius Dimmer" height:200
(

-- UI
group "Channel 01"
(
dropdownlist ch01lst items:(for i in ch01cnt collect i)
checkbutton ch01add "Patch" Width: 100
button ch01rem "Unpatch" Width: 100
)

--Events

	on ch01add changed true do
	(
		-- Define Variable
		objadd = PickObject count:1 rubberband:$aquarius.pos
		if isValidNode objadd do
		(
		-- Add to list
		append ch01cnt (objadd.name as string)
		ch01lst.items = (for i in ch01cnt collect i)		
		print ch01lst.items	
		-- Wiring
		paramWire.connect $Aquarius.modifiers[#FoaS_Aquarius_Dimmer][#ch01d] objadd.baseObject[#Multiplier] "ch01d"
		paramWire.connect $Aquarius.modifiers[#FoaS_Aquarius_Dimmer][#ch01c] objadd.baseObject[#Color] "ch01c"
		if objadd.type !=#omni do
		(
		paramWire.connect $Aquarius.modifiers[#FoaS_Aquarius_Dimmer][#ch01h] objadd.baseObject[#Hotspot] "radtodeg(ch01h)"
		paramWire.connect $Aquarius.modifiers[#FoaS_Aquarius_Dimmer][#ch01f] objadd.baseObject[#Falloff] "radtodeg(ch01f)"		
		)
		-- Deactivate button
		ch01add.state = false
		)
	)
	
	on ch01rem pressed do
	(
		if ch01lst.items.count > 0 and ch01lst.selection > 0 do
		(
		objrem = getNodeByName ch01lst.selected
		if isValidNode objrem do
			(
				--DeWiring
				paramWire.disconnect objrem.multiplier.controller
				paramWire.disconnect objrem.color.controller
				if objrem.type !=#omni do
				(				
				paramWire.disconnect objrem.hotspot.controller
				paramWire.disconnect objrem.falloff.controller
				)
				--Remove from list
				if ch01lst.items.count > 0 and ch01lst.selection > 0 then deleteItem ch01cnt ch01lst.selection
				ch01lst.items = (for i in ch01cnt collect i)
				print ch01lst.items
			)
		)
	)
	
	on AquDimmer open do
	(
		ch01lst.items = (for i in ch01cnt collect i)
		print ch01lst.items
	)
)
)

At the moment its functional for what its designed to do. However, there are shortcommings as of yet. for one, if you were to press “Patch” and then unpress “Patch” without selecting a node, it will still act as if “Patch” were down and pick a node nonetheless. How can I stop it from trying to select a node when “Patch” is up.
Also, it wont work anylonger if you change the name of your lights. Is there a way to circumvent this?
Also, I am working on a filter so that all you can chose is lights.

Bad idea using a checkbutton for this, also you are passing TRUE instead of a variable as handler argument, thus the handler does not know whether you are checking or unchecking.

Better use a Pickbutton which has on somePickButton picked obj do () handler where obj will be the object you picked or undefined if you cancelled.
You can also pass a filter function to the pickbutton so it only let’s you select objects you haven’t picked yet, or certain classes or whatever…

Yeah, it is much easier using a pickbutton, you are right. I just swapped them out.

Now onto the Filter ^__^.

New problem, lol – full of them aren’t I?

I’ve made it so that when you press “Patch” it will wire the lights multiplier and color, but will only wire hotspot and falloff if a certain checkbox is down.
When i press “unpatch” I want to make it so it will only disconnect parameters that are wired to Aquarius.
I dont really know if im heading in the right direction with this, so could some one point me the proper way?

on ch01rem pressed do
	(
		if ch01lst.items.count > 0 and ch01lst.selection > 0 do
		(
		objrem = getNodeByName ch01lst.selected
		if isValidNode objrem do
			(
				--DeWiring
				-- COMPATIBILITY WITH LIGHTS
				if superclassof objrem == light do
					(
						paramWire.disconnect objrem.multiplier.controller
						paramWire.disconnect objrem.color.controller
						if objrem.type != #omni do
							(
								if objrem.hotspot.controller.getwireparent == #ch01h do
									(
									paramWire.disconnect objrem.hotspot.controller
									paramWire.disconnect objrem.falloff.controller
									)
							)
					)
				
				--Remove from list
				if ch01lst.items.count > 0 and ch01lst.selection > 0 do ( deleteItem ch01cnt ch01lst.selection )
				ch01lst.items = (for i in ch01cnt collect i)
				print ch01lst.items
					
			)
		)

the line

if objrem.hotspot.controller.getwireparent == #ch01h do

is what I’m having trouble with. What im trying to do is have it say “if the parent of the controller of objrem’s hotspot is the ch01h parameter of aquarius do …”