[Closed] setVert

Hi Paul,
Perhaps you could assign all vertices positions at once. Not sure if it will work for what you need, but here are two slightly modified versions of your function. While both runs faster, one uses less memory and the other is 2X faster.

fn pasteVerts2 objs =
   (
   	poSetVert = polyOp.setVert
   	for o in objs where isValidNode o and classOf o == Editable_Poly do
   	(
   		vIdx = #{}
   		vPos = #()
   		tm = o.transform.row4
   		for v in copiedVertPostions do
   		(
   			append vIdx v.index
   			append vPos (v.pos + tm)
   		)
   		poSetVert o vIdx vPos
   	)
   	completeRedraw()
   )
   
   fn pasteVerts3 objs =
(
	poSetVert = polyOp.setVert
	for o in objs where isValidNode o and classOf o == Editable_Poly do
	(
		vIdx = #{}
		vPos = #()
		tmX = (o.transform.row4).x
		tmY = (o.transform.row4).y
		tmZ = (o.transform.row4).z
		for v in copiedVertPostions do
		(
			append vIdx v.index
			append vPos [v.pos.x+tmX, v.pos.y+tmY, v.pos.z+tmZ]
		)
		poSetVert o vIdx vPos
	)
	completeRedraw()
)

Ah good point, didn’t even think of that. Thanks. I will see if the undo is still an issue.

Why not use the polyop.MoveVert?
It works faster for large amount of verts.
For the Undo problem – did you tried the theHold.begin() and theHold.Accept()/theHold.Cancel()?

[i]

[/i]

polyop.setvert is undoable. you don’t have to do anything to make it “better” undoable…
if you want to be 100% sure that the Hold begun do convert all nodes to poly before a setting verts.

probably the reason of the crash is that you go out of vertex number range for some objects. so you have to check the number before setting some index…

and! don’t collect vertex structures. collect just their positions. if you want to keep the index as well do it with you own structure:

struct VData (index, pos)
 fn collectVerts nodes: =
 (	
 	if nodes == unsupplied do nodes = selection
 	for node in nodes where iskindof node Editable_Poly collect
 	(
 		for v=1 to node.numverts collect VData v (polyop.getvert node v)
 	)
 )
 fn releaseVerts vdata nodes: =
 (	
 	if nodes == unsupplied do nodes = selection
 	for k=1 to vdata.count where iskindof (node = nodes[k]) Editable_Poly do
 	(
 		converttopoly node -- not really necessary
 		for v in vdata[k] where v.index <= node.numverts do (polyop.setvert node v.index (v.pos + node.transform.pos))
 		update node
 	)
 )
 
 delete objects
 s = sphere radius:10 pos:[-40,0,0]
 b = box pos:[40,0,20]
 converttopoly objects
 
 vv = collectVerts nodes:objects
 objects.pos = [0,0,0]
 /*	
 releaseVerts vv nodes:#(b,s) 
 -- or
 releaseVerts vv nodes:#(s,b) 
 */

I could not measure any noticeable difference using polyop.SetVert or polyop.MoveVert in my tests, as far as speed or memory usage when setting multiple vertices at once.
16 models 160K polygons, 75ms 4950456L

I don’t know if I am getting the same results as you. I’ve tryied the following and I don’t see a big difference:

(
   st = timestamp()
   for v in $.verts do v.index
   format "time:%
" (timestamp()-st)
   )
   time:93
   (
   st = timestamp()
   for v in $.verts do true
   format "time:%
" (timestamp()-st)
   )
   time:80

I wasn’t going out of range on the vert indexes as they are all morph targets and identical.

Thanks for the thoughts here. I will give it an update tomorrow and see what I can get and post with the results if it is worth it.

Yes, this one is slower. Tested on 300K vertices model.

(
    st = timestamp()
    for v in $.verts do v.pos
    format "time:%
" (timestamp()-st)
    )
    time:237

Neither the Undo+Leak can crash Max?

you are right… the memory leaking corrupts gc … as a result you would see a message kinda ”blah,blah,blah… if you see this message you suck!”
so… don’t let your memory go wild!