[Closed] select visible faces?

--Get the viewport TMatrix, invert to get the equivalent of a camera transformation
theTM = inverse (viewport.getTM()) 
--Loop through all geometry objects that have EPoly Base Object
for theObj in Geometry where classof theObj.baseobject == Editable_Poly do
(
theFacesToSelect = #{} --ini. a bitArray to collect faces to select
numFaces = polyOp.getNumFaces theObj   --get the number of polygons in the EPoly
--loop from 1 to the number of polygons and set the corresponding bit in the bitArray
--to true if the normal of the polygon as seen in camera space has a positive Z,
--and false if it is negative or zero (facing away from the camera)
for f = 1 to numFaces do  
  theFacesToSelect[f] = (in coordsys theTM polyOp.getFaceNormal theObj f).z > 0 
--finally, set the selection in the object
polyOp.setFaceSelection theObj theFacesToSelect 
)
--when done with all, redraw the views - if a Poly SO level is selected, 
--the selection will be updated in the viewport...
redrawViews() 
 

 
theTM = inverse (viewport.getTM()) 
for theObj in Geometry where classof theObj.baseobject == Editable_Poly do
(
theFacesToSelect = #{} 
numFaces = polyOp.getNumFaces theObj 
for f = 1 to numFaces do 
  theFacesToSelect[f] = (in coordsys theTM polyOp.getFaceNormal theObj f).z <= 0 
polyOp.setFaceSelection theObj theFacesToSelect 
theObj.Hide #Face
)
redrawViews() 

This is easy, but not really necessary.
The changes:
*Instead of >0, the check does <= 0 for the normals to select the back-faces.
*Then, after setting the face selection, it calls Hide for the selected Faces.

It doesn’t make much sense because Max does fast back-face culling in the viewports by default, and the renderer also renders single-sided (skipping just the faces we removed) unless you force 2-sided…

I don’t see this as a useful tool, just as an “accademic” example of comparing face normals in camera space. (Max 7 users can also check out the MAXScript FAQ for a very similar example I added in the last update…)