[Closed] scripted plugin – possible?

Yes it’s fully possible.
demands some work, but there is examples in the maxscript manual that should get you going.
“scripted geometry” in the help file.
there’s an example that creates geometry and has custom spinners for it’s parameter.

Cheers for that, I have a mission ahead.

Cg.

scripted plugin – possible?

We have to talk here about technical and practical possibility. Technically is possible for sure. If anyone (developers of meshsmooth, spherify, push, and relax modifier) could do it, why can you not?

The practical side of this problem is that you have to do all mesh operation on trimesh level. So only the meshop interface can help you.

If the push and relax algorithms are pretty simple, the meshsmooth and spherify are not trivial. The main problem for all these algorithms realization is we don’t really know vertex normals. So you have to calculate them yourself and keep tracking of all changes.

I would estimate the time of developing this plug-in in MXS by myself is about 3-4 day.

So I would stay with the modifier stack solution adding extra modifiers to convert the Hedra to Poly, apply face IDs, extrude faces and weld vertices.

Do I understand correctly Dennis that you’re saying that with a scripted plugin, you have to do everything with tri mesh operations and it would be a long process to replicate the functionality of the modifiers that I’m using so I should skip trying to do it as a custom primitive and just use my script with the modifiers as I already have it now?

http://www.scriptspot.com/3ds-max/scripts/primitive-maker

Thanks for that MGernot. This project for me though, is more about the learning than the result. So using someone else’s script kind of defeats the purpose for me in this case. Looks like a cool script though. Pretty sure I’ll use it for other things.

Cheers,

Cg.

OK, I’ve got step 0 and 1. With a radius spinner. Tesselation, I have an idea for a sort of meshsmooth-type tesselation. Spherify I figure I should be able to do with the use of unit vector stuff. I’ll post back when/if I’ve made some progress.

Cheers Dennis.

OK, work’s been a bit busy so I’ve only just had a chance to have a go at a tessellation algorithm. This is my first try at edge to face-center tessellation. To start with, I thought I’d just look at how to tessellate polygons with polyop methods to keep it as simple as possible and then move up from there. I decided to keep the original vert ordering like meshsmooth does (but not turbosmooth)

Very open to comments/crits/discussion

  (
 	obj = convertto (copy selection[1]) polyMeshObject
 	newObj = convertTo(editable_mesh name:"Tesselated") polyMeshObject
 	newObj.transform = obj.transform

  	baseVertCount = polyop.getnumverts obj
  	baseFaceCount = polyop.getNumFaces obj
  	baseEdgeCount = polyop.getNumEdges obj
  	
  	newFaceVerts = #()
  	newEdgeVerts = #()
  	
  	-- recreate existing verts on new object so the original verts are retained like meshsmooth, not like turbosmooth where they are reordered.
  	for i = 1 to baseVertCount do polyop.createVert newObj (polyop.getVert obj i)
  
  	-- create new verts on new object at center of all original faces
  	-- collect an array of new face verts indexed by face numbers
  	for i = 1 to baseFaceCount do
  	(
  		polyop.createVert newObj (polyop.getFaceCenter obj i)
  		append newFaceVerts (baseVertCount + i)
  	)
  	
  	-- create new verts on new object at center of all original edges
  	-- collect an array of new edge verts indexed by edge numbers
  	for i = 1 to baseEdgeCount do
  	(
  		edgeVerts = polyop.getEdgeVerts obj i
  		polyop.createVert newObj (((polyop.getVert obj edgeVerts[1])+(polyop.getVert obj edgeVerts[2]))/2)
  		append newEdgeVerts (baseVertCount + baseFaceCount + i)
  	)
  	
  	-- iterate thru all original faces
  	for i = 1 to baseFaceCount do
  	(
  		faceEdges = polyop.getFaceEdges obj i
  		
  		-- iterate thru all original verts of face
  		faceVerts = polyop.getFaceVerts obj i
  		
  		for j = 1 to (faceVerts.count) do
  		(
  			-- find the 2 edges that this vert and face share
  			vertEdges = (polyop.getEdgesUsingVert obj (faceVerts[j]))as array
  			for k = (vertEdges.count) to 1 by -1 do if findItem faceEdges (vertEdges[k]) == 0 do deleteItem vertEdges k
  			
  			newPolyVerts = #((newFaceVerts[i]),newEdgeVerts[(vertEdges[2])],(faceVerts[j]),newEdgeVerts[(vertEdges[1])])
  			
  			polyop.createPolygon newObj newPolyVerts
  		)
  	)
  	
  	delete obj
  	update newObj
  	select newObj
  )
  

And this is my first attempt at a meshop spherify algorithm. Was a lot easier than tessellate.

 (
 	obj = convertToMesh (copy selection[1])
 	undo off
 	(
 		vertDistanceTotal = 0
 		
 		vertCount = meshop.getNumVerts obj
 		objCenter = obj.center
 		
 		for i = 1 to vertCount do vertDistanceTotal += (distance objCenter (meshop.getvert obj i))
 		
 		vertDistAverage = vertDistanceTotal/vertCount
 		
 		for i = 1 to vertCount do
 		(
 			vertVector = (meshop.getVert obj i) - objCenter
 			meshop.setVert obj i (((vertVector/(length vertVector)) * vertDistAverage) + objCenter)
 		)
 	)
 	selection[1].baseobject = copy obj.baseobject
 	delete obj
 )