[Closed] Script to arcive and mail?

Well…anyway… here’s a working example:

(
	dnConvert=dotnetClass "System.Convert"
	dnUTF8 = dotNetObject "System.Text.UTF8Encoding"
	rijn=(dotnetClass "System.Security.Cryptography.SymmetricAlgorithm").Create()
	bKey=#(1,2,3,4,5,6,7,8,9,0,1,2,3,4,5,6,7,8,9,0,1,2,3,4,5,6,7,8,9,0,1,2)
	bIV=#(1,2,3,4,5,6,7,8,9,0,1,2,3,4,5,6)
	
	arDir = getdir #archives
	theINI=arDir+@"\UAS_settings.ini"
	fExists=getfilesize theINI
	if fExists!=0 then
	(
		
		encText=dnConvert.FromBase64String (getINISetting theINI "UAS Settings" "Password")
		memStream = dotnetObject "System.IO.MemoryStream" 
		cStreamMode=(dotnetClass "System.Security.Cryptography.CryptoStreamMode")
		cStreamTransform=rijn.CreateDecryptor bKey bIV
		cStream=dotnetObject "System.Security.Cryptography.CryptoStream"  memStream cStreamTransform cStreamMode.Write
		cStream.Write encText 0 encText.Count
		cStream.FlushFinalBlock()
		cipherBytes=memStream.ToArray()			
		memStream.Close()
		cStream.Close()

		dectext=dnUTF8.GetString cipherBytes
		
		theFTP=getINISetting theINI "UAS Settings" "FTP"
		theUsername=getINISetting theINI "UAS Settings" "Username"
		thePassword=decText
	)
	else
	(
		theFTP=@"ftp://ftp.google.com/"
		theUsername="anonymous"
		thePassword="password"	
	)
	
	rollout rUpload "Upload"
	(
		button btn_Archive "Archive" across:2 align:#left
		button btn_Upload "Upload" align:#right
		progressbar pb_Upload
		button btn_site "?" align:#center
	
		local webClient = dotnetObject "System.Net.WebClient"	
		
		fn UploadProgressChanged sender  args =
		(
			pb_Upload.value=args.ProgressPercentage
		)

		fn UploadFileCompleted sender args =
		(
			if args.Error==undefined then print "Upload finished" else print "An error as occurred"
		)

		on rUpload open do
		(
			dotnet.addEventHandler webClient "UploadProgressChanged" UploadProgressChanged
			dotnet.addEventHandler webClient "UploadFileCompleted" UploadFileCompleted
		)
		on btn_Archive pressed do
		(
			max file archive
		)
		on btn_Upload pressed do
		(									
			theFile = getFilenameFile maxFilename
			theZip = (arDir+@"\"+theFile+".zip")
			fExists=getfilesize theZip
			if fExists!=0 then
			(
				print "Upload started"
				theRemote=theFTP+theFile+".zip"
				theUri=dotnetObject "System.Uri" theRemote
				webClient.Credentials = dotnetObject "System.Net.NetworkCredential" theUsername thePassword
				webClient.UploadFileAsync theUri theZip
			) else print "Upload aborted"
		)
		
		on btn_site pressed do
		(
			process=dotnetclass "System.Diagnostics.Process"
			process.start "http://www.dimensao3.com/al"
		)
	)
	
	rollout sFTP "Setup FTP"
	(
		edittext txt_host "Host:" text:@"ftp://ftp.google.com" labelOnTop:true
		edittext txt_username"Username:" text:"anonymous" labelOnTop:true
		edittext txt_password "Password:" text:"password" labelOnTop:true
		button btn_save "Save settings"
		
		on btn_save pressed do
		(		
			
			encText=dnUTF8.GetBytes txt_password.text
			memStream = dotnetObject "System.IO.MemoryStream"
			cStreamMode=(dotnetClass "System.Security.Cryptography.CryptoStreamMode")
			cStreamTransform=rijn.CreateEncryptor bKey bIV
			cStream=dotnetObject "System.Security.Cryptography.CryptoStream"  memStream cStreamTransform cStreamMode.Write
			cStream.Write encText 0 encText.Count
			cStream.FlushFinalBlock()
			cipherBytes=memStream.ToArray()			
			memStream.Close()
			cStream.Close()

			enctext=dnConvert.ToBase64String cipherBytes
			
			deleteFile theINI
			setINISetting theINI "UAS Settings" "FTP" theFTP
			setINISetting theINI "UAS Settings" "Username" theUsername
			setINISetting theINI "UAS Settings" "Password" encText
		)
		
		on sFTP open do
		(
			txt_host.text=theFTP
			txt_username.text=theUsername
			txt_password.text=thePassword
		)
		
		on txt_host changed eText do
		(
			theFTP=eText
		)
		on txt_username changed eText do
		(
			theUsername=eText
		)
		on txt_password changed eText do
		(
			thePassword=eText
		)		
	)	
	
	mainFloat=newRolloutFloater "Upload Archived Scenes" 300 290
	addRollout rUpload mainFloat
	addRollout sFTP mainFloat
)