I am using the following code to render to texture:
fn renderToTexture obj renderSize outputFile = (
select obj
bi = obj.INodeBakeProperties
map = DiffuseMap()
map.outputSzX = renderSize
map.outputSzY = renderSize
map.targetMapSlotName = "Diffuse Color"
map.filename = outputFile
bi.addBakeElement map
bi.bakeEnabled = true
render rendertype:#bakeSelected outputwidth:map.outputSzX outputheight:map.outputSzY outputfile:map.filename progressBar:true
bi.removeAllBakeElements()
)
And here are the steps I followed:
Create object
Run above script -> creates texture of one side
Run render texture dialog -> creates expected texture
Run above script again -> creates expected texture
So it seems the render texture dialog performs some extra steps to prepare the object for RTT.
Does anyone know what are these steps and how to script them?
thanks,
Richard
May try posting some images and/or files that show what your problem is. From your description I have no idea what issue(s) you are running into.
-Eric
I’ve attached 2 textures rendered from a pyramid. ‘initial_texture’ is with the above script before running the RTT dialog. And ‘expected_texture’ is with the above script after running the RTT dialog.
What do you have enabled in the RTT dialog? Is it the automatic mapping or something else? Hard to diagnose without all the information.
Sorry wish I could be more help,
-Eric
In the RTT dialog all I do is add a DiffuseMap, then press render.
I noticed after using the RTT dialog there is an “Automatic Flatten UVs” in the object modifier list. Could that be my missing link?
And is there an API for this? I didn’t see it in the documentation.
You can dig through the Macro_BakeTextures.mcr. Everything RTT does is done by maxscript and all of the code is in the file. The actual code can be found in lines 741-773:
if applyObjectUnwrap then
(
-- create a new autoflatten unwrapper
if _debug do format " Create new object unwrap_uvw
"
unwrapMod = unwrap_UVW()
unwrapMod.setAlwaysEdit false
unwrapMod.setMapChannel bakeChannel_Obj
unwrapMod.setFlattenAngle flattenAngle
unwrapMod.setFlattenSpacing flattenSpacing
unwrapMod.setFlattenNormalize true
unwrapMod.setFlattenRotate flattenRotate
unwrapMod.setFlattenFillHoles flattenFillHoles
unwrapMod.setApplyToWholeObject true
unwrapMod.name = "Automatic Flatten UVs"
unwrapMod.setDebugLevel 0
setAppData unwrapMod RTT_UnwrapMod_AppData_Index #object
-- add it to the object
-- add directly to the object to avoid groupness
addModifier curObj unwrapMod
-- & flatten things
unwrapMod.flattenMapByMatID \
flattenAngle \
flattenSpacing \
true \
2 \
flattenRotate \
flattenFillHoles
-- or use instead of true: autoUnwrapMappingProps.cNormalize.checked \
) -- end, create new Object Level unwrapper
-Eric
yeah I’ve been wading through that macro but it’s a mess – 400 line functions, masses of global variables, etc
I was hoping someone had done this before.
I was able to isolate what I needed from that macro! In case someone needs to script RTT in the future here it is:
fn unwrap obj = (
flattenAngle = 45.0
flattenSpacing = 0.02
flattenRotate = true
flattenFillHoles = true
unwrapMod = unwrap_UVW()
unwrapMod.setAlwaysEdit false
unwrapMod.setMapChannel 1
unwrapMod.setFlattenAngle flattenAngle
unwrapMod.setFlattenSpacing flattenSpacing
unwrapMod.setFlattenNormalize true
unwrapMod.setFlattenRotate flattenRotate
unwrapMod.setFlattenFillHoles flattenFillHoles
unwrapMod.setApplyToWholeObject true
unwrapMod.name = "Automatic Flatten UVs"
unwrapMod.setDebugLevel 0
setAppData unwrapMod 0x41dd73d5 #object
addModifier obj unwrapMod
unwrapMod.flattenMapByMatID flattenAngle flattenSpacing true 2 flattenRotate flattenFillHoles
)
fn renderToTexture obj renderSize outputFile = (
select obj
unwrap obj
fPath = getFilenamePath outputFile
fName = getFilenameFile outputFile
fType = getFilenameType outputFile
bi = obj.INodeBakeProperties
map = DiffuseMap()
map.outputSzX = renderSize
map.outputSzY = renderSize
map.filename = fName
map.fileType = fType
bi.addBakeElement map
bi.bakeChannel = 1
bi.bakeEnabled = true
render rendertype:#bakeSelected outputwidth:renderSize outputheight:renderSize outputfile:outputFile
bi.removeAllBakeElements()
bi.bakeEnabled = false
)
Note that the renderToTexture function had to be updated because the previous was rendering a blank image after unwrapping.