[Closed] return new vertices/edges/faces after polyOp?

Depending on the operation, polyOp will return different data. If a polyOp member function doest not return what you want then you almost always have options.

Here’s an example.

fn Test =
(
	epObj = (convertToPoly (box()))	--:First we make a poly box
	(polyOp.setEdgeSelection epObj 1) --:Now we select an edge
	epObj.SelectEdgeRing() --:From that edge we select a ring
	
	originalVerts = #{1..(polyOp.getNumVerts epObj)} --:Now we store the current vert list for the whole model
	epObj.ConnectEdges() --:Now we connect the selected edges, adding new edges and verts in the process.
	
	newVerts = #{1..(polyOp.getNumVerts epObj)} - originalVerts --:Now we subtract the model's current vert list from the original
		
	polyOp.setVertSelection epObj newVerts --:Now we select the new verts
	
	epObj.ConvertSelection #vertex #edge requireAll:true --:If we want the new edges that were created from that op, we can do this.
	
	select epObj
	subObjectLevel = 2
)

Test()

So in this case, we leveraged the power of bitarray subtraction to get only the new verts. I’d recommend looking into bitarray manipulation a good bit, as it’s very powerfull for interrogating meshes.

As for ID reordering, generally operations that change topology simply append IDs to the data structures, but be carefull to inspect exactly what happens when you make changes. If you remove topology, the IDs can become reordered, but the impact of this depends on the operation.

Hope that makes sense. Let me know if you have any questions.

-Dave

That totally answers my questions. Thanks for the reply. I’ll do some research , especially on bitarrays and get back to you if I have any questions ,if thats ok.

Jamell