[Closed] render problems please help

how are you changing the objects and more importantly when are you changing them?

well here is the tricky bit. I have developed a script that animates vray proxies. Basically the vray proxy has a filename which is just a network path to an external file which is the vray proxy object. I have managed to write a script that changes this path per frame of the animation so if you have 100 vray proxy files over 100 frames the proxy should update. Im sure the path is changing as i get the listner to print the path of the proxy per frame during rendering the animation.

any ideas?

Hi Nebille,

you should be able to use the pre-render / post-render option in the render dialog.

Theoretically you should also be able to build a callback for this. If all of this fails, why not try my famous ‘render monkey’? he’s very cute and works hard and also has a sense of humour (not funny when you have a deadline)

 ------------------------------------------------------------
 --	Render Monkey
 --	www.joshuanewman.net
 --	written		:03/11/2004
 --	modified	:26/03/2006
 ------------------------------------------------------------
 --
 -- use this utility will load a maxfile and apply a 
 -- pre-render script for each frame in a sequence.
 
 global fl,ps
 rollout rendermonkey "Monkey Magic < :" width:178 height:350
 (
 	group "Parameters"
 	(
 		button ad "Choose MAX file" width:260
 		spinner fr "Frame Start:" type:#integer
 		spinner tl "Frame End:" type:#integer
 		spinner st "Frame Step:" type:#integer range:[-100,100,1]
 	)
 	group "Pre Render"
 	(
 		button pr "Pre Render script" width:260
 		checkbox prsa "Active:"
 	)	
 	button execute "Monkey!" width:278 height:40
 	label l1 "\xa9 2004 Joshua Newman" across:2 offset:[-8,0]
 	hyperlink hl "www.joshuanewman.net" address:"www.joshuanewman.net" offset:[4,0]	
 	
 	on pr pressed do
 	(
 		x=getopenfilename caption:"Choose script file" types:"Maxsciprt(*.ms)|*.ms|All|*.*|"
 		if x!=undefined then
 		(
 			ps=x
 			pr.text=filenamefrompath ps
 			prsa.checked=true
 		) else 
 		(
 			print "Invalid Maxscript file!
No script selected."
 			ps=undefined
 			pr.text="Pre Render script"
 			prsa.checked=false
 		)
 	)
 
 	on ad pressed do
 	(
 		x=getopenfilename caption:"Choode max file:" types:"Max(*.max)|*.max|All|*.*|"
 		if x!=undefined then
 		(
 			fl=x
 			ad.text=filenamefrompath fl
 		) else print "Invalid file!"
 	)
 	on execute pressed do
 	(
 		if fl!=undefined then
 		(
 			for i=fr.value to tl.value by st.value do
 			(
 				loadmaxfile fl quiet:true
 				if (prsa.checked==true) and (ps!=undefined) then
 				(
 					try (filein ps)
 					catch (messagebox "Error in pre-render script!" title:"Render Monkey!")
 				)
 				render frame:i
 			)
 			messagebox "Rendering Finished!" title:"Render Monkey!"
 		) else
 		(
 			messagebox "Please choose a Max file to render!" title:"Render Monkey!"
 		)
 	)
 )
 
 newroll=newrolloutfloater "Render Monkey." 300 287 750 80
 addrollout rendermonkey newroll
 
 

Josh.

thanks josh i will give it a go although i have pre render and postrender scripts running already. This may cause a conflict. I will let you know the result

nebille

you can run multiple files in the monkey by using ‘filein’ in a parent script.

happy monkey!

J.