[Closed] prob with loop assigned controllers instancing

Heya Folks,

I’m working on a script to assign an array of controllers to an object by assigning the first controller in the array, then assigning a list controller, then finally running through the entries from 2 on in the array and assigning each to the available slots of the list controller

My problem is that if I do the loop as described above the controllers become instanced and the objects pop to a new position unexpectedly. If however I skip assigning the first array controller and directly put on the list controller it doesn’t cause this problem.

Has anyone seen this before or know of the syntax to make each controller unique?

Here’s a script that will make three bones, store them in an array and apply the function to them – it’s set to work properly at the moment by not assigning the first controller, you’ll see the three lines commented that cause my problem.

-- Make an array for our bones to feed into the freezetrans function

Bonearray = #()

b1 = bonesys.createbone [0,0,0] [50,0,0] [0,0,1]
append BoneArray b1

b2 = bonesys.createbone [50,0,0] [100,0,0] [0,0,1]
append BoneArray b2

b3 = bonesys.createbone [100,0,0] [150,0,0] [0,0,1]
append BoneArray b3

b2.parent = b1
b3.parent = b2

-- function name, object to apple the fn to, array of position controllers, array of rotation controllers, position controller to set active, rotation controller to set active

fn FreezeTrans obj ThePosContArray TheRotContArray ActivePosCont ActiveRotCont =
(
	-- Set Up position lists - This works fine by keeping the objects original pos controller
	
	obj.position.controller = position_list()
	obj.position.controller.setname 1 ThePosContArray[1][2] as string
	
	-- However, if I assign the first controller of the PosArray it instances all 
    -- other controllers from then on and makes the bones pop. Comment the above two lines and uncomment the three under
	
	-- Commented to stop bones popping to another position
	
	/*
	obj.position.controller = ThePosContArray[1][1] -- Sets the default controller as the first cont in the array
	obj.position.controller = position_list() -- Then assigns our list controller
    obj.position.controller.setname 1 ThePosContArray[1][2] as string -- Names the first entry in the list controller
	*/
	

	-- 	Loop through other positions and assign controllers based on posarray count
	
	if ThePosContArray.count > 1 then
	(
		for p = 2 to ThePosContArray.count do
		(
			obj.position.controller.available.controller = ThePosContArray[p][1]
			obj.position.controller.setname p ThePosContArray[p][2] as string
		)
	)
		
	obj.position.controller.SetActive ActivePosCont
	
    -- do the same job with the rotations - I havent included the problems above as they're the same with rotations too

	obj.rotation.controller = Rotation_list()
	obj.rotation.controller.setname 1 TheRotContArray[1][2] as string
	
	if TheRotContArray.count > 1 then
	(		
		for r = 2 to TheRotContArray.count do
		(
			obj.rotation.controller.available.controller = TheRotContArray[r][1]
			obj.rotation.controller.setname r TheRotContArray[r][2] as string
		)
	)
	
	obj.Rotation.controller.SetActive ActiveRotCont
	
)

-- make an array with controller types and names to assign

TempPosArray = #(#(position_xyz(),"Frozen_Position"),#(position_xyz(),"Zero_Position"))
TempRotArray = #(#(Euler_xyz(),"Frozen_Rotation"),#(Euler_xyz(),"Splay_Rotation"),#(Euler_xyz(),"Linked_rotation"),#(Euler_xyz(),"Zero_rotation"))

for i = 1 to bonearray.count do
(
	FreezeTrans bonearray[i] TempPosArray TempRotArray 2 4
)

Any ideas how to solve this?

Thanks again,

John