[Closed] PolyStepper script

An ugly solution: use

sleep

before moving each vert

Try with

sleep

Execute the code from this post to see what sleep can do.

guys! ‘sleep’ is a debug function in all programming languages. don’t use it for anything else.

here is a little toy for anyone who wants to play with “stepper” idea:

  try(destroydialog pfs_geo_Rollout) catch()
  global pfs
  global geo
  rollout pfs_geo_Rollout "PFS and GEO by denisT" 
  (
  	group "Startup: "
  	(
  		button delete_all "Delete All" width:180 offset:[0,0]
  	)
  	on delete_all pressed do undo "Delete All" on delete objects
  		
  	group "Particle Flow: "
  	(
  		checkbox showpart_ch "Show Particle Ticks" checked:on
  		checkbox numbering_ch "Show Particle ID" checked:on
  		spinner rate_sp "Rate: " range:[0,1e9,30] type:#integer fieldwidth:56
  		spinner speed_sp "Speed: " range:[0,1e9,100] type:#integer fieldwidth:56
  		spinner divergence_sp "Divergence: " range:[0,1e9,0] type:#integer fieldwidth:56
  		spinner life_sp "Life Span: " range:[0,1e9,30] type:#integer fieldwidth:56
  		label direction_lb "Direction:" across:2 align:#right offset:[-38,6]
  		dropdownlist direction_dd items:#("Vertical","Center Out","Random 3D","Random Horizontal") width:120 align:#right offset:[0,2]
  		button create_pfs "Create Particles" width:180 offset:[0,2]
  --		button show_pfs "Show Particles Toggle" width:180 offset:[0,-2]
  	)
  	on show_pfs pressed do undo "Show PF" on if isvalidnode (pfs = getnodebyname "_theParticles") do pfs.ishidden = not pfs.ishidden
  	
  	group "Geometry: "
  	(
  		checkbox showticks_ch "Show Vertex Ticks" checked:on
  		label type_lb "Type:" across:2 align:#right offset:[-38,6]
  		dropdownlist type_dd items:#("Sphere","Box","Plane","Line","Curve") width:120 align:#right offset:[0,2]
  		button create_geo "Create Geomerty" width:180 offset:[0,2]
  --		button show_geo "Show Geometry Toggle" width:180 offset:[0,-2]
  	)
  	on show_geo pressed do undo "Show GEO" on if isvalidnode (pfs = getnodebyname "_theGeometry") do geo.ishidden = not geo.ishidden
  	
  	local ops = #()
  	
  	fn getDirection = case direction_dd.selection of
  	(
  		1: 0
  		2: 2
  		3: 3
  		4: 4
  	)
  	on create_pfs pressed do --undo "Create" on 
  	(
  		if isvalidnode (pfs = getnodebyname "_theParticles") do delete pfs
  		theHold.Begin()
  		pfs = PF_Source name:"_theParticles" X_Coord:0 Y_Coord:0 Emitter_Length:40 Emitter_Width:40 \
  			Quantity_Viewport:100 Show_Logo:on Show_Emitter:on Emitter_Type:2 wirecolor:blue
  				
  --		particleFlow.BeginEdit()
  		op1 = Birth name:"_birth" Emit_Stop:(3000f).ticks rate:rate_sp.value type:1
  		op2 = Position_Icon()
  		op3 = Speed name:"_speed" speed:speed_sp.value variation:5 reverse:on divergence:divergence_sp.value direction:(getDirection())
  --		op4 = Age_Test name:"_age_test" test_value:(30f).ticks
  		op5 = DeleteParticles name:"_delete_particles" type:2 life_span:(life_sp.value as time).ticks
  		op6 = DisplayParticles name:"_display_particles" show_numbering:numbering_ch.state color:pfs.wireColor type:(if showpart_ch.state then 2 else 0)
  		op7 = RenderParticles name:"_render" type:3
  		ev1 = Event name:"_event"
  		ev1.SetPViewLocation (pfs.X_Coord) (pfs.Y_Coord+100)
  --		particleFlow.EndEdit()
  		
  		ev1.AppendAction op1
  		ev1.AppendAction op2
  		ev1.AppendAction op3
  --		ev1.AppendAction op4
  		ev1.AppendAction op5
  		ev1.AppendAction op6
  		pfs.AppendAction op7
  		pfs.AppendInitialActionList ev1
  --		pfs.activateParticles on
  		theHold.Accept "Make PF"
  		
  		ops = #(op1,op2,op3,op4,op5,op6,op7)
  		pfs
  	)
  	fn constrain value minimum maximum = (amax minimum (amin maximum value))
  
  	fn particleBindController index number node pf =
  	(
  		c = point3_script()
  		c.AddConstant "index" index
  		c.AddConstant "number" number
  		c.AddObject "pf" (NodeTransformMonitor node:pf)
  		c.AddNode"node" node
  		str = "(if isvalidnode pf and index <= (count = pf.numParticles()) then (pf.getParticlePosition (count - index + 1)) else [0,0,0])*(inverse node.transform)"
  		c.setExpression str
  		c
  	)
  	fn bindPoints node pf = 
  	(
  		suspendEditing()
  		animatevertex node #all
  		cc = for c in (getPointControllers node) where c != undefined collect c 
  		for k=1 to cc.count do replaceinstances cc[k] (particleBindController k cc.count node pf)
  		resumeEditing()
  		ok
  	)
  	on create_geo pressed do undo "Create theGeo" on 
  	(
  		if isvalidnode (geo = getnodebyname "_theGeometry") do delete geo
  		geo = case type_dd.selection of
  		(
  			1: converttomesh (geosphere segments:2)
  			2: converttomesh (box width_segs:1 length_segs:1 height_segs:1)
  			3: converttomesh (plane width_segs:4 length_segs:4) 
  			4: 
  			(
  				geo = converttosplineshape (helix turns:0.5)
  				open geo 1
  				geo
  			)
  			5: 
  			(
  				geo = converttosplineshape (ngon nsides:24 circular:on)
  				open geo 1
  				geo
  			)
  		)
  		geo.name = "_theGeometry"
  		geo.vertexTicks = showticks_ch.state
  		geo
  		
  		if isvalidnode (pfs = getnodebyname "_theParticles") do bindPoints geo pfs
  	)
  
  	fn updateGeo geo = if isvalidnode (geo = getnodebyname "_theGeometry") do for c in (getPointControllers geo) do c.update()
  	fn update = if iskindof pfs PF_Source do undo "Change PF" on
  	(
  		if isvalidnode (pfs = getnodebyname "_theParticles") do 
  		(
  			pfs._event._display_particles.type = if showpart_ch.state then 2 else 0
  			pfs._event._display_particles.show_numbering = numbering_ch.state
  			pfs._event._birth.rate = rate_sp.value
  			pfs._event._speed.speed = speed_sp.value
  			pfs._event._speed.divergence = divergence_sp.value
  			pfs._event._delete_particles.life_span = (life_sp.value as time).ticks
  			
  			pfs._event._speed.direction = getDirection()
  			
  			pfs.activateParticles on
  			updateGeo geo
  		)
  	)
  	
  	on showpart_ch changed state do update()
  	on numbering_ch changed state do update()
  	on rate_sp changed val do update()
  	on speed_sp changed val do update()
  	on divergence_sp changed val do update()
  	on life_sp changed val do update()
  	on direction_dd selected sel do update()
  	
  	on showticks_ch changed state do if isvalidnode (geo = getnodebyname "_theGeometry") do geo.vertexTicks = state
  )
  createdialog pfs_geo_Rollout width:200
  

PS: It’s a debug code (not optimized, not beautified, etc.). So please don’t use it as a sample how to write the max script code

to gazybara:
as you see I’ve agreed with the most your solutions …

Is it difficult to achive such a movemet of the verts?
I attach a file as an example of how it should look like fluid-like movement of polystepper.