[Closed] Pipes Generator

http://vimeo.com/54060892

here is my idea based on 3D grid. as you see the system never takes already taken cells.

  try(destroydialog PipeGen) catch()
  rollout PipeGen "Pipe Generator" width:200
  (
  	fn roundFloat d pre:1.0 =
  	(
  		local d = (d as float)/pre
  		local v = if (d - (v1 = floor d)) > ((v2 = ceil d) - d) then v2 else v1 
  		v*pre
  	)
  	fn roundPoint3 p = 
  	(
  		p.x = roundFloat p.x
  		p.y = roundFloat p.y
  		p.z = roundFloat p.z
  		p
  	)
  
  	button begin_bt "Begin" width:190 align:#left offset:[-8,0]
  	label info_lb "" --across:2
  	--spinner limit_sp type:#integer range:[0,5,3] fieldwidth:44 align:#right offset:[4,-1]
  	button grow_bt "Grow" width:190 align:#left offset:[-8,0]
  	
  	local size = 1.0
  	local grid_size = 100
  	local block, joint
  	local ends = #(), joints = #()
  	local shifts = #([-1,0,0],[1,0,0],[0,-1,0],[0,1,0],[0,0,-1],[0,0,1])
  	
  	fn getSplits = 
  	(
  		k = random 1 100
  		case of
  		(
  			(k < 85): 1 
  			(k < 94): 2 
  			(k < 98): 3 
  			(k < 100): 4 
  			 default: 5
  		)
  	)
  	
  	local taken = #()
  	fn takePoint p = 
  	(
  		d = p + grid_size
  		if taken[d.x] == undefined do taken[d.x] = #() 
  		if taken[d.x][d.y] == undefined do taken[d.x][d.y] = #{}
  		taken[d.x][d.y][d.z] = on
  	)
  	fn isFree p limit:0 = 
  	(
  		d = p + grid_size
  		taken[d.x] == undefined or taken[d.x][d.y] == undefined or not taken[d.x][d.y][d.z]
  	)
  	fn getAvailable p =
  	(
  		for s in shifts where isFree (p+s) collect s
  	)
  	on begin_bt pressed do undo "Begin Pipe" off
  	(
  --		seed 0
  		delete objects
  		block = box width:(size/4) length:(size/4) height:size widthsegs:1 lengthsegs:1 heightsegs:1 wirecolor:orange showFrozenInGray:off isselected:on
  		joint = box width:(size/2) length:(size/2) height:(size/2) widthsegs:1 lengthsegs:1 heightsegs:1 wirecolor:yellow showFrozenInGray:off 
  		centerpivot joint
  		block.objectoffsetpos -= [0,0,1]
  		taken = #()
  		takePoint block.center
  		ends = #(block)
  		joints = #(joint)
  		info_lb.text = "1 / 1"
  		gc()
  	)
  	fn getEnds = for node in objects where not node.isFrozen collect node
  	on grow_bt pressed do undo "Grow Pipe" on
  	(
  		max create mode
  		new = #()
  		for b in selection do 
  		(
  			added = off
  			turned = off
  			for k=1 to getSplits() do
  			(
  				ss = getAvailable b.pos 
  				d = roundPoint3 b.dir
  --				format "% %
" d ss
  				if finditem ss d != 0 do for i=1 to 20 do append ss d
  				if ss.count > 0 then
  				(
  					s = ss[random 1 ss.count]
  					if s != d do
  					(
  						turned = on
  						j = instance joint pos:b.pos dir:d showFrozenInGray:off
  						append joints j
  					)
  					p = roundPoint3 (b.pos + s)
  					d = roundPoint3 (p - b.pos)
  
  					added = on
  					n = instance block pos:p dir:d showFrozenInGray:off
  					append new n
  					takePoint p
  				)
  				else added = on
  			)
  			if not added do append new b
  		)
  		objects.wirecolor = green
  		joints.wirecolor = yellow
  		new.wirecolor = orange
  		select new
  		info_lb.text = objects.count as string + " / " + new.count as string
  		completeredraw()
  	)
  )
  createdialog PipeGen
  

every time you can change selection to start new branch