[Closed] MAX_Script_Help – > Creating Groups By Selection

Try this:

try destroydialog GroupCreator catch()

fn getuserstring default:"Groupname" =
(
	RenameDialog = dotNetObject "MaxCustomControls.RenameInstanceDialog" default
	DialogResult = RenameDialog.Showmodal()
	dotnet.compareenums RenameDialog.DialogResult ((dotnetclass "System.Windows.Forms.DialogResult").OK)
	Outputstring = RenameDialog.InstanceName
	Outputstring
)

rollout GroupCreator "---"
(
	local mygroup
	
	button BTN_MakeGroup "Make Group"
	
	on BTN_MakeGroup pressed do
	(
		if mygroup == undefined then
		(
			mygroup = group selection name:(getuserstring default:"Groupname") select:true
		)
		else select mygroup
	)
)

createdialog GroupCreator

Note:
The dotnetdialog for renaming is originally not mine, i found it here on the forum iirc.

Hey guys,

Thanks for the quick reply!,

Heilandzack – So this is really close, however I realize I wasn’t being really clear on what I am trying to accomplish. I am not actually trying to build “Groups” I am trying to make a button that selects certain objects.

For example:

Select a number of objects in the scene with “Rectangular selection region tool” then > run a script that automatically creates a selection button based on the objects I have selected . That way, when I press the button that the script created, It will automatically select those objects.

This is what the final result would look like:

– Create a Scene with eight generic Standard free spot lights then run this script!

try(destroyDialog test)catch()

rollout test “Test” width:191 height:73
(
button btn1 “Grp1” pos:[11,10] width:50 height:50

button btn2 "Grp2" pos:[74,10] width:50 height:50

button btn5 "Deselect" pos:[135,9] width:50 height:50

on btn1 pressed do
(
	select #($Fspot003, $Fspot002, $Fspot007, $Fspot006)
)
on btn2 pressed do
(
	select #($Fspot004, $Fspot001, $Fspot005,$Fspot008)
)

on btn5 pressed do 
(
	clearSelection()
)

)

Createdialog Test

The problem here though is I have to manually input the selections into the script. I want to make a script that will input these selections based on what I have manually grabbed in the scene. I hope that makes sense.

Why you don’t use the Named Selection Set? You can create as many selSets as you want and won’t be limited by the UI of the script.

But:
-craete separate variable for each button. This variable will holds the selected objects.
-when you press the button the script will check if this variable is a collection of obejcts(an array). If it is not – put the selected objects to the variable. If the variable is an array – select all objects in this array.
You can add some visual feedback to tell you which button will select obejcts.

(
	try(destroyDialog test)catch()
	rollout test "Test" width:191 height:73
	(
		local grp1Arr = undefined
		local grp2Arr = undefined
		
		button btn1 "Grp1" pos:[11,10] width:50 height:50
		button btn2 "Grp2" pos:[74,10] width:50 height:50
		button btn5 "Deselect" pos:[135,9] width:50 height:50
		
		function StoreSelection =
		(
			if selection.count != 0 do
				arr = selection as array
		)
		
		on btn1 pressed do
		(
			if grp1Arr == undefined then
				grp1Arr = StoreSelection()
			else
				select grp1Arr
			
		)
		on btn2 pressed do
		(
			if grp2Arr == undefined then
				grp2Arr = StoreSelection()
			else
				select grp2Arr
			
		)
		on btn5 pressed do
		(
			clearSelection()
		)
	)
	Createdialog Test
)

Hey Miauu

I really like this option, if I understand it correctly the action would be. ” Select the objects in the scene, then press the button” <- the button saves whatever is selected as the variable and then plays it back whenever pressed.

In this scenario it would be very beneficial for the button to ask “what would you like to name this button” (referring to the selection of objects that have just been selected)

Now, how the heck would you program that? I am way way too green, but I am learning. = )

Hey Miauu

Woah, this is perfect! I know it seems like a weird way to do things, but this coincides with how lighting programming works. So from that point of view its a much more organic transition from lighting console to 3Ds GUI.

I have a few other interesting problems I need solved as well. I will start a new thread as I continue to work on this project.

Thank you!

try (destroydialog CollectSelSet) catch()
rollout CollectSelSet "Collect SelSet" width:204
(
	edittext selset_name_ed "Selection Set Name:" labelOnTop:on fieldwidth:190 align:#left offset:[-5,0]
	button collect_bt "Collect" width:190 align:#left offset:[-5,4] \
		tooltip:"Add Selection To Selection Set
 + CTRL	 - Replace"
	
	on collect_bt pressed do undo "Collect SelSet" on 
	(
		if (name = selset_name_ed.text) != "" do
		(
			nodes = selection as array
			if (selectionSets[name] == undefined) or keyboard.controlpressed then selectionSets[name] = nodes
			else
			(
				selectionSets[name] = join nodes selectionSets[name]
			)
		)
	)
)
createdialog CollectSelSet

finally i would cool to have ‘full service’ (list, add, remove, rename, find, etc.). but currently it would be too advenced.

list is cool, but its most problem is reverse setup – when selset added, deleted, renamed, etc. not in the tool, or/and undo/redo related to selsets was happened