Notifications
Clear all
Dec 30, 2016 9:34 am
Deleted post to improve struct.
Dec 30, 2016 9:34 am
Deleted post to improve struct.
Dec 30, 2016 9:34 am
Ok. Here’s a struct for Arrays Query using some kind of ‘lambda expressions’.
Just uses one aditionnal Global for holding the lambda expression.
There are some examples following the struct to show its use. It should be nice to implement a Comparer for arrays that are not ‘simple arrays’ of numbers or strings.
Edited: struct created only once.
struct ArrayQuery
(
mainArray,
ResultArray,
-- Query Functions
fn _where LA =
(
LA = LA as string
if (assignPos = findString LA "=>") == undefined do (ResultArray = #(); return this)
fnExpression = (substring LA 1 (assignPos - 1)) + " = " + (substring LA (assignPos+2) -1)
try
(
LA = execute ("fn GlobalLambdaFN " + fnExpression)
testValidity = LA ResultArray[1]
)
catch
(
ResultArray = #(); return this
)
if classof testValidity != BooleanClass do (ResultArray = #(); return this)
ResultArray = for item in ResultArray where (LA item) collect item
return (this)
),
fn Change LA =
(
LA = LA as string
if (assignPos = findString LA "=>") == undefined do (ResultArray = #(); return this)
fnExpression = (substring LA 1 (assignPos - 1)) + " = " + (substring LA (assignPos+2) -1)
try
(
LA = execute ("fn GlobalLambdaFN " + fnExpression)
testValidity = LA ResultArray[1]
)
catch
(
ResultArray = #(); return this
)
ResultArray = for item in ResultArray collect (LA item)
return (this)
),
-- Filter Functions
fn MakeUnique =
(
ResultArray = makeUniqueArray ResultArray
return (this)
),
fn Intersect otherArray =
(
ResultArray = for item in ResultArray where (findItem otherArray item != 0) collect item
return (this)
),
fn Except otherArray =
(
ResultArray = for item in ResultArray where (findItem otherArray item == 0) collect item
return (this)
),
fn Union otherArray =
(
ResultArray = makeUniqueArray (mainArray + otherArray)
return (this)
),
-- Final Functions
fn Select =
(
Result = for item in ResultArray collect item
ResultArray = deepCopy mainArray
return Result
),
fn Count =
(
Result = ResultArray.count
ResultArray = deepCopy mainArray
return Result
),
fn Sum =
(
arrayClass = classof ResultArray[1]
suma = case arrayClass of
(
string:""
integer:0
integer64:0
float:0
double:0
default:-1
)
if suma == -1 do return (ResultArray = deepCopy mainArray; false)
for item in ResultArray do (suma += item)
ResultArray = deepCopy mainArray
return suma
),
fn _Sort = -- Should implement a Comparer
(
arrayClass = classof ResultArray[1]
canSort = case arrayClass of
(
string:true
integer:true
integer64:true
float:true
double:true
default:false
)
if (not canSort) do return (ResultArray = deepCopy mainArray; false)
Result = sort ResultArray
ResultArray = deepCopy mainArray
return Result
),
fn FindAllIndex LA = -- 'index' == reserved word for array index
(
LA = LA as string
if (assignPos = findString LA "=>") == undefined do return (ResultArray = deepCopy mainArray; false)
fnExpression = (substring LA 1 (assignPos - 1)) + " = " + (substring LA (assignPos+2) -1)
try
(
LA = execute ("fn GlobalLambdaFN index " + fnExpression)
testValidity = LA 1 ResultArray[1]
)
catch
(
return (ResultArray = deepCopy mainArray; false)
)
if classof testValidity != BooleanClass do return (ResultArray = deepCopy mainArray; false)
ResultIndex = for id = 1 to ResultArray.count where (LA id ResultArray[id]) collect id
ResultArray = deepCopy mainArray
return ResultIndex
),
fn FindIndex LA = -- 'index' == reserved word for array index
(
LA = LA as string
if (assignPos = findString LA "=>") == undefined do return (ResultArray = deepCopy mainArray; false)
fnExpression = (substring LA 1 (assignPos - 1)) + " = " + (substring LA (assignPos+2) -1)
try
(
LA = execute ("fn GlobalLambdaFN index " + fnExpression)
testValidity = LA 1 ResultArray[1]
)
catch
(
return (ResultArray = deepCopy mainArray; false)
)
if classof testValidity != BooleanClass do return (ResultArray = deepCopy mainArray; false)
ResultIndex = 0
for id = 1 to ResultArray.count where (LA id ResultArray[id]) while (ResultIndex == 0) do (ResultIndex = id)
ResultArray = deepCopy mainArray
return ResultIndex
),
on create do
(
ResultArray = deepCopy mainArray
)
)
(
myArray = #(5, 3, 9, 8, 6, 7, 2, 0, 5)
otherArray = #(4, 1, 3, 9, 8, 6)
--myArray = #("one", "two", "three", "four", "five")
--otherArray = #("two", "four")
--myArray = #(#(5, 3), #(9, 8), #(6, 7), #(2, 0))
--otherArray = #(#(4, 1), #(9, 8))
QArray = ArrayQuery myArray
kk = QArray.Sum()
format "Sum All= %
" kk
kk = QArray.Count()
format "Count All= %
" kk
kk = (QArray._where("x => x < 6")).Select()
format "Select numbers Less than 6 = %
" kk
kk = ((QArray._where(#'x => x < 6')).MakeUnique()).Select()
format "Unique numbers Less than 6 = %
" kk
kk = (QArray._where(#'x => x < 6')).Sum()
format "Sum numbers Less than 6 = %
" kk
kk = (QArray._where(#'x => x < 6')).Count()
format "Count numbers Less than 6 = %
" kk
kk = ((QArray._where(#'x => x > 6'))._where(#'x => ((mod x 2) == 0)')).Count()
format "Count numbers Greater than 6 and even= %
" kk
kk = ((QArray._where(#'x => x > 6'))._where(#'x => ((mod x 2) == 1)')).Select()
format "Select numbers Greater than 6 and odd= %
" kk
kk = ((QArray._where(#'x => x > 6'))._where(#'x => ((mod x 2) == 1)')).Sum()
format "Sum numbers Greater than 6 and odd= %
" kk
kk = (QArray.Intersect(otherArray)).Select()
format "Common items= %
" kk
kk = (QArray.Except(otherArray)).Select()
format "Different items= %
" kk
kk = (QArray.Union(otherArray)).Select()
format "All Distinct items= %
" kk
kk = ((QArray._where(#'x => x > 6')).Intersect(otherArray)).Select()
format "Common items greater than 6= %
" kk
kk = ((QArray._where(#'x => x > 6')).Intersect(otherArray)).sum()
format "Sum of Common items greater than 6= %
" kk
kk = ((QArray._where(#'x => x < 6')).MakeUnique())._Sort()
format "Sort Unique numbers Less than 6 = %
" kk
kk = QArray._Sort()
format "Sort array= %
" kk
kk = (QArray.Change(#'x => x ^ 2')).Select()
format "Power2 of items= %
" kk
kk = ((QArray._where(#'x => x < 5')).Change(#'x => x ^ 2')).Select()
format "Power2 of items Less than 5 = %
" kk
kk = ((QArray.Change(#'x => x ^ 2'))._where(#'x => x < 5')).Select()
format "Power2 that is Less than 5 = %
" kk
kk = ((QArray._where(#'x => x > 5')).Change(#'x => bit.intAsChar (x+65)')).Select()
format "Convert to Character items Greater than 5 = %
" kk
kk = QArray.FindAllIndex(#'x => x > 5')
format "Index of items Greater than 5 = %
" kk
kk = (QArray.MakeUnique()).Select()
format "Make unique array= %
" kk
kk = (QArray.MakeUnique()).FindAllIndex(#'x => x > 5 and index > 4')
format "Index greater than 4 of items Greater than 5 after making unique= %
" kk
kk = (QArray.MakeUnique()).FindIndex(#'x => x > 5 and index > 4')
format "Find Index greater than 4 of first ocurrence of item Greater than 5 after making unique= %
" kk
kk = (QArray._where(#'x => x * 6')).Select() -- Check Error
format "ERROR. Where_Function is not boolean = %
" kk
kk = (QArray._where(#'x => x < "g"')).Select() -- Check String
format "Select items Less than \"g\" = %
" kk
kk = (QArray._where(#'item => item[1] < 5')).Select() -- Check Sub_Arrays
format "Select pairs whith first index Less than 6 = %
" kk
kk = ((((QArray._where(#'x => x > 2')).Change(#'x=>x*2')).Except(otherArray)).MakeUnique()).Select()
format "Take numbers greater than 2. Multiply them by 2. Select all that are not in the other array. Make the result array unique= %
" kk
OK
)
Page 4 / 4
Prev