[Closed] Getting merged objects from callback

I’d do something like this, but probably put it in a struct to avoid lots of globals:

global theNodeEventCallback
global merging = false
global newNodes

function newNodes s e = (
	if merging do (
		for obj in e do (
			print (getAnimByHandle obj)
		)
	)
)

callbacks.addScript #filePreMerge "merging = true" id:#test
callbacks.addScript #filePostMerge  "merging = false" id:#test
theNodeEventCallback = nodeEventCallback added:newNodes


/*
To remove the callbacks:

callbacks.removeScripts id:#test

theNodeEventCallback = undefined  --make reference of node callback undefined
gc light:true --run a garbage collection to completely remove node callback

/*

Ah, it appears that the filePostMerge callback is fired before the nodeEventCallback.

This code works, and the nodeEventCallback is only enabled when merging.

global theNodeEventCallback
global newNodes

function newNodes s e = (
	for obj in e do (
		print (getAnimByHandle obj)
	)
	theNodeEventCallback.enabled = false
)

callbacks.addScript #filePreMerge "theNodeEventCallback.enabled = true" id:#test
theNodeEventCallback = nodeEventCallback added:newNodes
theNodeEventCallback.enabled = false

/*
To remove the callbacks:

callbacks.removeScripts id:#test

theNodeEventCallback = undefined  --make reference of node callback undefined
gc light:true --run a garbage collection to completely remove node callback

*/

here is my version:

global mergeResult
fn preMergeControl = (mergeResult = objects.count)
fn postMergeControl = (mergeResult = for k = mergeResult + 1 to objects.count collect objects[k])

callbacks.removeScripts id:#merge_control
callbacks.addScript #filePreMerge "preMergeControl()" id:#merge_control
callbacks.addScript #filePostMerge  "postMergeControl()" id:#merge_control

Interesting different approaches, thanks.