[Closed] floating viewer max

no, pardon my English, I have not explained well,
attempt to do this…

I don’t think it’s possible in MXS and I should point out that this was a wish often asked for from ’99-2002, but every time it came up the development manager shot the idea down (on what I think are reasonable grounds). However, you can find a highly limited floating viewport easter egg in the MAX Finder utility, if I recall.

kinda

(

	rollout tRO "floating viewer ;)" width:((gw.getWinSizeX())/2) height:((gw.getWinSizeY())/2)
	(
		fn setROImg =
		(
			--set custom viewport and shading settings here
			
			SetDialogBitmap  tRO (gw.getviewportDIB())
			
			OK
		)
		
		timer clock interval:500
		
		on clock tick do setROImg()
	)
	createdialog tRO bmpstyle:#bmp_stretch bitmap:(bitmap 1 1 color:orange) style:#(#style_resizing, #style_titlebar, #style_border, #style_sysmenu, #style_toolwindow)
	
)

fantastic! this is exactly what I need

How can I change to camera for permanent mode?

What do you mean with permanent mode?

I didn’t read the code, but i assume that what is being done is capture in real time the active viewport, so the only way you can do that is modify the script to capture a camera viewport, but you’ll need to have a viewport with a camera view configured on it, and work in the other viewports.

Cheers.

possible yeah but with a whole lot of annoying flickering
to avoid that you could change the active viewport-border color to the background color
as the comment(s) in the code suggest its quite simple to extend the script with custom settings

you could also switch the current viewType to persp then just set the tm thats been saved before but that would be fairly equivalent to an immovable camera not a viewport to monitor

(

	rollout tRO "floating viewer ;)" width:((gw.getWinSizeX())/2) height:((gw.getWinSizeY())/2)
	(
		local fixed_to_viewport = true	-- if set to true the same viewport is going to be displayed at all times
		
		local vpI = 0
		
		fn setROImg =
		(
			disableSceneRedraw()
			
			--set custom viewport and shading settings here
			local oldVPI = viewport.activeViewport
			
			if fixed_to_viewport == true do 
			(
				viewport.activeViewport = vpI
			)
			
			SetDialogBitmap  tRO (gw.getviewportDIB())
			
			--revert to old viewport and shading settings here
			if fixed_to_viewport == true do 
			(
				viewport.activeViewport = oldVPI
			)
			
			enableSceneRedraw()
			OK
		)
		
		timer clock interval:500
		
		on clock tick do setROImg()
		
		on tRO open do vpI = viewport.activeViewport
	)
	createdialog tRO bmpstyle:#bmp_stretch bitmap:(bitmap 1 1 color:orange) style:#(#style_resizing, #style_titlebar, #style_border, #style_sysmenu, #style_toolwindow)
	
)

thank you very much

Very interesting the way you used to create the new floating viewport. However, if you create a floating window, for example, the camera viewport, and maximize another viewport (for example, perspective), it will give error. 🙁
If it was possible do that then, we would have a great resource for animation.

Muito interessante a maneira que você usou para criar a nova janela. Porém, se você criar a janela flutuante, por exemplo, da vista da câmera, e maximizar uma outra vista, vai dar erro.
Se fosse possível fazer isso, então teriamos um ótimo recurso para animação.