[Closed] dotNet UI

Oct 26, 2011 4:05 pm

This is great.
The more I become familiar with the help file the easier and more smooth things will develop as well.

I’ll go ahead and make another round of developments over the weekend and the beginning of next week before my next post.
I’ll have some new things and ideas to try and conquer.
Till next week!

Have a good weekend guys.

JokerMartini

Oct 26, 2011 4:05 pm

Nice work John, looks like you’re getting up to speeds with dotNet very quickly Looking forward to the results you post up soon.

Oct 26, 2011 4:05 pm

Now I’m wanting to combine these two ideas.
This first script snippet is the main base of the script.
The second snippet is the new addition I want to mix into the first. I want to use the second snippet to create all the children buttons so they are vertically aligned.
Special thanks to Paul Neal for the second snippet of code.

Snippet 1


global exampleDotNetTool	
struct exampleDotNetToolStr
(
	--// components
	form,
	parentBtns,
	childBtns,
	
	
	--// handlers
	fn parentClicked s e =
	(
		for b in exampleDotNetTool.childBtns do b.visible = b.tag == s.tag
	),
	
	fn childClicked s e =
	(
		format "child of group % pressed
" s.tag
	),
	
	
	--// initialization functions
	fn controlFactory type text backColor X Y W H tag =
	(
		local ctr = dotNetObject type
		ctr.text = text
		ctr.bounds = dotNetObject "System.Drawing.Rectangle" X Y W H
		ctr.backColor = (dotNetClass "System.Drawing.Color").fromArgb backColor.a backColor.r backColor.g backColor.b
		ctr.tag = tag
		ctr
	),	
	
	fn initializeForm =
	(
		form = dotNetObject "maxCustomControls.maxForm"		
		form.showInTaskbar = false
		form.text = "Dotnet Tool Example"
		form.bounds = dotNetObject "System.Drawing.Rectangle" 100 100 250 300
		form.controls.addRange parentBtns
		form.controls.addRange childBtns		
		local sysPointer = dotNetObject "System.IntPtr" (windows.getMaxHWND())
		local maxHandle = dotNetObject "maxCustomControls.win32HandleWrapper" sysPointer
		form.show maxHandle
	),

	fn initializeControls =
	(		
		--//Variables
		dir = @"C:\Users\IEVFX\Desktop	rash\scripts" --//Main Scripts directory
		dirArray = GetDirectories (dir+"/*") --//Get subfolders in directory
		parentFolders = for d in dirArray collect (trimright (filenameFromPath d) "\\") --//Array which stores just the names of the subfolders
		local parentBtnDefs = #()
		local childBtnDefs = #()
		local pos = 10

		--//Create Groups
		for i = 1 to parentFolders.count do (
			sFiles = #()
			sFiles = getFiles (dirArray[i] + "*.ms*")
			
			groupName = (parentFolders[i] as string)
			groupColor = #((color 74 134 230),(color 119 187 68),(color 203 73 73))--//Blue,Green,Red,
			
			newGroup = #("Button", groupName,groupColor[i], pos, 10, 70, 30, i)
			append parentBtnDefs newGroup
			
 			--// Create children for each group
 			if sFiles.count > 0 do
 			(
				cPos = 40
				
				for n = 1 to sFiles.count do
 				(
 					ChildName = getFIleNameFile sFiles[n]
					newChild = #("Button", ChildName,groupColor[i], pos, cPos, 70, 30, i)
					append childBtnDefs newChild
					
					cPos += 30
 				)
 			)
			pos +=70
		)
		
		parentBtns = for b in parentBtnDefs collect (controlFactory b[1] b[2] b[3] b[4] b[5] b[6] b[7] b[8])
		for b in parentBtns do dotnet.addEventHandler b "Click" parentClicked		
		childBtns = for b in childBtnDefs collect (controlFactory b[1] b[2] b[3] b[4] b[5] b[6] b[7] b[8])
		for b in childBtns do dotnet.addEventHandler b "Click" childClicked
		for b in childBtns do b.visible = false
		initializeForm()		
	),

	init_trigger = initializeControls() --auto-initialize the controls on struct creation
)

::exampleDotNetTool = exampleDotNetToolStr()

Snippet 2


try(form.close())catch()

Ccolor = dotnetclass "system.drawing.color"	
	
bt=dotNetObject "button"
bt.flatStyle=bt.flatStyle.flat
bt.backColor=bt.backColor.blue
bt.flatappearance.bordercolor = Ccolor.blue
bt.flatappearance.mouseoverbackcolor = Ccolor.lightblue
bt.flatappearance.mousedownbackcolor = Ccolor.blue	
bt.size=dotNetObject "system.drawing.size" 24 64
bt.location=dotNetObject "system.drawing.point" 10 10

font=dotNetObject "System.Drawing.Font" "Arial" 8
brush=dotNetObject "System.Drawing.SolidBrush" (dotNetClass "system.drawing.color").white

fn btPaint sender arg=
(
    --Set a variable to make it easier to use for the graphics engine.
    g=arg.graphics
    --Move the starting point of the text over and down.
    g.TranslateTransform 6 58
    --Rotate the text -90 degrees. 
    g.RotateTransform -90
    --Draw the text.
    g.DrawString "Button" font brush (dotNetObject "system.drawing.pointF" 0 0)
)

dotNet.addEventHandler bt "paint" btPaint
dotNet.setLifeTimeControl bt #dotNet

form=dotNetObject "form"
form.controls.add bt

form.show()

Oct 26, 2011 4:05 pm

Looks nice. By the way you may want to have a look at some other button controls that ship with 3ds Max. the default ones are OK but they don’t exactly take on the max theme.

Autodesk includes a few dll’s created by devExpress that are well worth checking out.

Try playing with this:


btn1 = dotNetObject "DevExpress.XtraEditors.simpleButton"

You can get really nice looking buttons with these settings that fit in with max 2010+:


btn1.lookandfeel.UseDefaultLookAndFeel = false
btn1.lookAndFeel.style = btn1.lookAndFeel.style.ultraFlat
btn1.imageList = --Add imageList here for icons
btn1.backGroundImageLayout = btn1.backGroundImageLayout.center
btn1.appearance.backColor = (dotNetClass "System.Drawing.Color").transparent
btn1.allowFocus = false

1 Reply

lo1

(@lo1)

Joined: 11 months ago

Posts: 0

Oct 26, 2011 4:05 pm

Nice! Is this documented anywhere?

Oct 26, 2011 4:05 pm

These look very slick.
I like the appearance of these buttons. Thanks Tim

It seems to bug out when I run the code on this line.

“btn1.lookAndFeel.style = btn1.lookAndFeel.style.ultraFlat”


btn1 = dotNetObject "DevExpress.XtraEditors.simpleButton"		
btn1.lookandfeel.UseDefaultLookAndFeel = false
btn1.lookAndFeel.style = btn1.lookAndFeel.style.ultraFlat
btn1.imageList = --Add imageList here for icons
btn1.backGroundImageLayout = btn1.backGroundImageLayout.center
btn1.appearance.backColor = (dotNetClass "System.Drawing.Color").transparent
btn1.allowFocus = false

hForm = dotNetObject "System.Windows.Forms.Form" 
hForm.controls.add btn1
hForm.topmost = true
dotNet.addEventHandler mButton "click" whenButtonIsPressed 

--Finally display the image
hForm.show()

I wish the vertical aligning of the buttons was as easy as just having a rotate property on the button itself.

Why is the form dialog different from the dialog being created within the struc?
Is there limitations to one over the other.

4 Replies

(@timhawker)

Joined: 11 months ago

Posts: 0

Oct 31, 2011 7:37 pm

Look at the line below that. It is asking for an imageList but i didn’t provide one. Get rid of that line if you don’t want to add an icon imagelist. If you do add an imageList you will also need to tell it what imageIndex icon to use as well.

None than I can find which is a shame. I believe they included the devexpress dll’s to create the scene explorer, which uses a devexpress treelist:


dotNetObject "DevExpress.XtraTreeList.TreeList"

Search your 3ds Max install dir for “devExpress” and it will show a few dll’s that Autodesk have included since version 2009 I believe.

Edit:
Although there is no documentation from Autodesk, there is a HUGE amount of documentation on the devexpress website. If I’ve ever had a problem the answer has usually been found in their online support ticket forum. http://www.devexpress.com/

lo1

(@lo1)

Joined: 11 months ago

Posts: 0

Oct 31, 2011 7:37 pm

That’s just insane! They give us this incredible set of tools for free but fail to inform us of their existence for 4 years!

denisT

(@denist)

Joined: 11 months ago

Posts: 0

Oct 31, 2011 7:37 pm

lo1

incredible set of tools… incredible is a strong word in this context.

lo1

(@lo1)

Joined: 11 months ago

Posts: 0

Oct 31, 2011 7:37 pm

denisT

Ok, well… A set of tools.

Oct 31, 2011 7:37 pm

What would be the equivalent of a subrollout using dotNet? I want to try and do something like this next.

When you click the Offset the script would do what is the equivelant of a
fileIn (in maxscript) and those controls would then be loaded into this panel where the user could adjust the desired settings and options before applying the changes to the scene. Keeping in mind that these other *.ms files would be written only for use within this master script. You wouldn’t be able to go file>run>offset.ms and it work properly.

In this case the fileIn *.ms would consist of something similar to this…which is just ui controls and whatnot. If it makes more sense I can create an example of what I’m after using maxscript. Just let me know.


form=dotNetObject "form"

nud=dotNetObject "System.Windows.Forms.NumericUpDown"
nud.DecimalPlaces=2
nud.Increment=.1
nud.maximum=10
nud.minimum=-10
nud.ReadOnly=false
enableAccelerators=false
showProperties nud

form.controls.add nud
form.show()

Oct 31, 2011 7:37 pm

I went ahead and made an example file.
Just extract and check it out. Run the masterDialog.ms

1 Reply

lo1

(@lo1)

Joined: 11 months ago

Posts: 0

Oct 31, 2011 7:37 pm

Firstly, an unrelated comment on your example:
The first time you run the script you will get an exception (start max afresh and run masterDialog.ms). This is because of scope issues.
Consider the following two lines:

fileIn "rlOffset.ms"
AddSubRollout rlMasterDialog.srContainer rlOffset

The exception occurs because rlOffset is undefined. Intuitively, you’d expect it to be fine as you just defined it a line before within the rlOffset.ms script.
Unfortunately, this is not how maxscript works. Upon entering the event handler, it evaluates all the variable withing the handler, and determines not their value, but what they are referring to.
So when the event handler is entered, if tries to determine what the variable rlOffset is, and does not find any such variable, so it determines it is an undefined local variable.
You must specifically tell maxscript to look for this variable in the global scope. There are two ways to do this:

explicitly declare the variable global: (“global rlOffset”)
use the special :: prefix to declare it global:

fileIn "rlOffset.ms"
AddSubRollout rlMasterDialog.srContainer ::rlOffset

A more technical explanation on how maxscript handles scope is given by Bobo in a thread I can’t find at the moment.

To try to answer your actual question, A possible solution is to declare a panel control within the files, containing all the child controls, and simply use the form.controls.add and form.controls.remove to switch between them.
This is what I did recently in the stamping module of my frame buffer tool, you can see how it works there if you wish (though it’s implemented in c# there).
I think the optimal method of implementation and structure depend on the intended use of the subpanels.