What I essentially want is to add an attribute to an object that has been imported (.obj), that attribute would hold the name of that object in the moment of importing. So if I import a model named “Human” I want to add an attribute to that model which would hold edittext/label “Human”, if I then rename the model from”Human” to “John” (i.e) i want the attribute to still hold the name/string “Human”.
here is the add attribute example code:
function addStringAttribute =
(
if attributeVariable != undefined then ( custAttributes.delete $ attributeVariable )
attributeVariable = attributes nameAttribute
(
parameters nameAttributeParameters rollout:nameAttributeParametersUI
( nameAttrParameter type:#string )
rollout nameAttributeParametersUI “NameAttribute”
( edittext nameAttr “originalName” text: $.name Height:17 width:130 Align:#center )
)
custAttributes.add $ attributeVariable
)
addStringAttribute()
My problem is that that edittext stays linked to the name so if I would rename “Human” to “John” attribute would also get changed. I want to remove that variable link that exists. Add the name of attribute at the time of evaluating/executing the script and leave it be. That is my problem. Hopefully I illustrated it clear enough. Thanks in advance.
global NameAttribute = attributes NameAttribute
(
fn getNode = (refs.dependentnodes (custattributes.getowner this) firstonly:on)
fn getName = (if (node = getNode()) != undefined then node.name else "")
parameters params rollout:params
(
internalName type:#string ui:ui_internalName
on internalName get name do
(
if name == undefined then getName() else name
)
)
rollout params "Internal Name"
(
edittext ui_internalName width:156 align:#left offset:[-12,0]
button reset_bt "Set Real Name" width:152 align:#left offset:[-8,2]
button rename_bt "Rename Node" width:152 align:#left offset:[-8,-2]
on reset_bt pressed do undo "Real Name" on internalName = getName()
on rename_bt pressed do undo "Rename Node" on (getNode()).name = internalName
)
)
delete objects
d = dummy isselected:on
custattributes.add d NameAttribute baseobject:on
This is great! It works and it has even more options that I needed.
Thank you very much
what options do you not need? i will remove them immediately