A simple build-in method could be using matchPattern(). Otherwise you could do it with RegEx, which is better and faster for this sort of things. But I think matchPattern() will do just fine.
Below is an example, not fully functional though.

(
  	
  	fn GetFilesFromFolder folder: =
  	(
  		files = #()
  		append files "wood-036_silver-fir-1_b.png"
  		append files "wood-036_silver-fir-1_d.png"
  		append files "wood-036_silver-fir-1_r.png"
  		append files "wood-036_silver-fir-2_b.png"
  		append files "wood-036_silver-fir-2_d.png"
  		append files "wood-036_silver-fir-2_r.png"
  		
  		for j in files do
  		(
  			print (matchPattern j pattern:"wood-036_silver-fir-*" ignoreCase:true)
  		)
  	)
  	
  	GetFilesFromFolder()
  	
  )

find all files in a directory that match a wildcard:

in our case the wildcard is *_?.png

files = getfiles (dir + "/*_?.png")

now we need a way to split filename on texture ‘name’ and texture ‘type’ specified by a latter… let’s do it as:

name = substring file 1 (file.count-1)
type = file[file.count]

(optional) check that a type is one of available

if (finditem #("b","d","r") type) > 0 do

group files by their base ‘name’. i would use a structure:

struct TextureStruct (base, textures = #())

we need a search method to find right group for a file:

fn findByBase list name =
(
    n = 0
    for k = 1 to list.count while n == 0 where list[k].base == name do n = k
    n
)

now we have everything to group:

files = getfiles (dir + "/*_?.png)
types = #("b","d","r") 
textures = #()
for file in files do 
(
    file = getfilenamefile file
    name = substring file 1 (file.count-1)
    type = file[file.count]
    if (finditem types type) > 0 do
    (
         if (k = findbybase textures name) == 0 do 
         (
              append textures (TextureStruct base:name)
              k = textures.count
         )
         append textures[k].textures file
     )
)

that’s it!

(not tested)

it would be better to use lower case for search and strings compare

спасибо Denis!

Thank you very much for the breakdown Denis.
I would be fascinated to see the regex version of this as well.

Jorge, you missed the part where I have hundreds of files to sort (with about 120 base file names).
Some of them have only the _d and _r suffix. Denis’ solution works wonders AND I learned a few things.

here is a regex version with better structuring:

struct TexturesData 
(
	TextureStruct = 
	(
		struct TextureStruct (file, base, type)
	),
	
private 
	pattern = "^(.*?)(_[b,d,r])$",
	regex = dotnetclass "System.Text.RegularExpressions.Regex",

	keys = #(), 
	values = #(),
	fn ensure key exact:off =
	(
		if (k = finditem keys key) > 0 then k else 
		(
			k = keys.count+1
			if not exact do 
			(
				append keys key
				append values #()
			)
			k
		) 
	),
public 
	fn appendvalue key value =
	(
		append values[ensure key] value
	),
	fn get key exact:on = values[ensure key exact:exact],
	fn getkeys = keys,
	fn getvalues = values,
	fn count = keys.count,
	fn contains key = finditem keys key > 0,
		
	fn parse filename add:off = 
	(
		file = getfilenamefile filename
		if regex.ismatch file pattern do
		(
			d = regex.match file pattern
			s = TextureStruct file:filename base:d.groups.item[1].value type:d.groups.item[2].value
			if add do appendvalue s.base s
			s
		)
	),
	fn group files reset:off = 
	(
		if reset do 
		(
			keys = #()
			values = #()
		)
		for file in files where iskindof (s = parse file) this.TextureStruct do 
		(
			appendvalue s.base s
		)
	),
	on create do ()
)
	
/*
a = TexturesData()

(
	files = #()
	append files "wood-036_silver-fir-1_b.png"
	append files "wood-036_silver-fir-1_d.png"
	append files "wood-036_silver-fir-1_r.png"
	append files "wood-036_silver-fir-2_b.png"
	append files "wood-036_silver-fir-2_d.png"
	append files "wood-036_silver-fir-2_r.png"

	a.group files
)
a.getkeys()
a.getvalues()

for key in a.getkeys() do format "key:% >> %
" key (a.get key)
*/

the pattern “^(.*?)([b,d,r])$” means – ” i don’t care how it starts but has to end with “?” where “?” is any letter of ‘b’, ‘d’, or ‘r’ “