[Closed] Change base node?

If you want instances of the sphere, you can say

 (
 s = sphere() --create a sphere
 for o in selection do o.baseobject = s.baseobject --instance its base to the selected nodes
 delete s --delete the sphere
 )
 

If you want copies, you can say

for o in selection do 
 (
 s = sphere()
 o.baseobject = s.baseobject
 delete s
 )

You can also pick a scene node to instance it’s base object:

(
 p = pickobject()
 if isValidNode p do 
 for o in selection do o.baseobject = p.baseobject
 )
 

You can add the line

MacroScript InstBO category:"Forum Help"

to each one of these to make them MacroScripts…

You could make it even better by ensuring there IS a selection first:

MacroScript InstBO category:"Forum Help"
(
on isEnabled return selection.count > 0 --enable button if anything selected
on Execute do
(
p = pickobject() --pick a scene node
 if isValidNode p do  --if the pick was valid
 for o in selection do o.baseobject = p.baseobject --instance the base node
)--end execute
)--end macro