[Closed] WPF in Max

Thanks for pointing that out. I was getting an error in 2010 for some reason, and I know that Autodesk updated the .Net version for 2011, which is why I thought it just wouldn’t work. But I’ll try looking into it some more and update the blog post.

That works too. The nice thing about using a WPF window is that you can do some pretty cool things with it visually, like completely changing the shape and other nice effects.

The downside is that if you want it to act like it’s part of Max, you have to manage the owner and the windows background and foreground colors manually. But putting the control in a Rollout or MaxForm using ElementHost gets you those things for free. And a rollout even lets you dock it.

Just for fun, I tried the WPF window with my progress bar and works perfectly, with the caveats I’ve already mentioned.

dotNet.loadAssembly @"<folder name>\ProgressBar\ProgressBar\bin\Debug\ProgressBar.dll"
  
  bar = dotNetObject "ProgressBar.UserControl1"
  frm = dotnetobject "System.Windows.Window"
  
  frm.title = "Progress"
  frm.width = bar.width + 16
  frm.height = bar.height + 34
  frm.windowStartupLocation = frm.windowStartupLocation.centerScreen
  frm.windowStyle = frm.windowStyle.toolWindow
  
  frm.content = bar
  
  frm.show()
  
  -- set number of steps to use
  bar.steps = 50
  
  -- loop through the steps
  for i = 1 to bar.steps do
  (
  	-- force the UI to update
  	(dotNetClass "System.Windows.Forms.Application").DoEvents()
  	-- increment one step and change label
  	bar.DoStep()
  	bar.ProgressLabel = "Thing " + i as string
  	sleep .05
  )
  
  frm.close()

Yep, definitely not a blocking issue, but something to be aware of.

Here is what the rollout version would look like…

-- load the progress bar library
 dotNet.loadAssembly @"<folder location>\ProgressBar\ProgressBar\bin\Debug\ProgressBar.dll"
 
 -- load the WPF Integration library needed to create the ElementHost control
 dotNet.loadAssembly @"C:\Program Files (x86)\Reference Assemblies\Microsoft\Framework\v3.0\WindowsFormsIntegration.dll"
 
 bar = dotNetObject "ProgressBar.UserControl1"
 size = [bar.width,bar.height]
 frm = rollout progressBar_RLT "Progress" width:size.x height:size.y
 (
 	dotNetControl eh "Integration.ElementHost" width:size.x height:size.y align:#left offset:[-14,-5]
 	
 	on progressBar_RLT open do
 	(
 		eh.child = bar
 	)
 )
 
 createDialog progressBar_RLT
 
 -- set number of steps to use
 bar.steps = 50
 
 -- loop through the steps
 for i = 1 to bar.steps do
 (
 	-- force the UI to update
 	(dotNetClass "System.Windows.Forms.Application").DoEvents()
 	-- increment one step and change label
 	bar.DoStep()
 	bar.ProgressLabel = "Thing " + i as string
 	sleep .05
 )
 
 destroyDialog progressBar_RLT

The only thing different is the creation of the rollout and then putting the controls inside of it. Note, I just figured out the you don’t really need the UserControl. Just put the ElementHost inside the rollout or window, and then the WPF control inside of that. I had the UserControl because I had originally created a generic “WPF host” control in C# which I was bringing into Max. But if you’re building it in Max to begin with, you don’t need it.

As far whether it would work in a modifier panel, I don’t know. It would just be another control in the rollout, so I’m assuming it would work the same as using it in a regular non-modifier rollout.