[Closed] UtilityPanel.OpenUtility causes 3ds max to hang

i changed callback event to #viewportChange … it doesn’t hang for me.

and #selectionSetChanged works OK.

PS. When you use callbacks.removeScripts with name of event you have to know that you are deleting all scripts registered with this event. It’s better to use your own id, and delete by id (and name of event if you like)

Thanks for the quick reply Denis!

I’m sorry about the earlier example I did, it seems that my problem is related to the radiosityProcessDone callback and not the utilitypanel.openutility.

Try this code (which hangs 3ds max here):

 (
 	global fnDoSomething
 	
 	fn fnDoSomething =
 	(
 		-- utilitypanel.openutility Assign_Vertex_Colors
 		callbacks.removeScripts #radiosityProcessDone id:#radiosityDone
 		try (selection.showVertexColors = on) catch()
 		try (utilitypanel.openutility Assign_Vertex_Colors) catch() -- Max crashes here?
 	)
 
 	rollout roTestRadiosity "RadiosityCB" width:162 height:78
 	(
 		button btnStart "Start" pos:[16,20] width:128 height:32
 		
 		on btnStart pressed do (
 			-- turn off the undo buffer and scene redraw (saves memory and increases speed)
 			with undo off with redraw off (
 				-- set the render to default_scanline_renderer
 				renderers.current = Default_Scanline_Renderer()
 				
 				-- setting the material ID:1 (default) to black material
 				meditMaterials[1] = standard()
 				meditMaterials[1].ambient = color 0 0 0
 				meditMaterials[1].diffuse = color 0 0 0
 				
 				-- assign black material to all objects in scene
 				$*.material = meditMaterials[1]
 			
 				-- create sky light in scene
 				SkyLight()
 				
 				-- if no radiosity solution exists
 				if(sceneRadiosity.radiosity == undefined) then (
 					-- assign a new radiosity effect to the scene
 					sceneRadiosity.radiosity = radiosity()
 				)
 				
 				-- set radiosity settings
 				sceneRadiosity.radiosity.Reset true true -- reset radiosity solution without showing a warning dialog
 				sceneRadiosity.radiosity.radInitialQuality = 95.0
 				sceneRadiosity.radiosity.includeSkylight = true
 				
 				-- add callback to continue after the radiosity is finished
 				callbacks.addScript #radiosityProcessDone "fnDoSomething()" id:#radiosityDone
 				
 				-- start radiosity
 				try (sceneRadiosity.radiosity.Start()) catch()
 			)
 		)
 	)
 
 	createDialog roTestRadiosity
 )
 

Last code works OK on my machine (MAX 2010 32-b) … I looked in and couldn’t find anything that might cause max crash except perhaps the memory issue. Try to call
(
gc light:on delayed:on
completeRedraw()
)
before openning utility.

By the way, do you know about AssignVertexColors interface? You don’t need Assign_Vertex_Colors utility. This utility is using this interface, and doing nothing more then that.

… and don’t create SkyLight on every button press or delete it after.

Thanks again for quick replies Denis. Maybe this is a bug that only happens in 3ds max 2009? I can’t get the utility panel to pop up without 3ds max bugging and hanging (have to terminate application by ctrl+delete). PS. my test scene consist of simple Editable Polys objects (like a couple boxes and spheres).

The AssignVertexColors Interface doesn’t do anything as far as I know. I’ve seen many reports that it’s broken on this forum. And I haven’t gotten it to work myself either… Is it fixed in 3ds max 2010?

Oh, and I will delete the skylight after the radiosity is finished.

That’s the code I’ve used earlier for doing automatic baking of vertex colors, I only added the settings I needed (ie: vpModifier.useRadiosity = true).

I tried your code example and it didn’t work either (no vertex colors showing up). The script adds the Vertex Paint modifiers, but doesn’t assign any vertex colors to the selected objects. I also added the useradiosity settings and enabled show vertex colors in viewport in object properties. Still it didn’t assign the vertex colors based on the radiosity solution. If I do it manually it works fine.

However I think I stumbled upon the solution! If I have the Assign Vertex Colors utility panel open before I run the code – it suddenly works! I just added the following at the top of the script:

 try (utilitypanel.openutility Assign_Vertex_Colors) catch() -- This is essential to make the Vertex Colors show up!
 

If only the utilitypanel.openutility wouldn’t cause max to hang as I run it from a callback function…

I’m going to download 3ds max 2010 trial to see if that will stop 3ds max from bugging up once the utilitypanel.openutility command is executed from a callback function.

Thanks again!

fn pressAssignVColor = 
(
name = "Assign" 
if (win = windows.getChildHWND #max "Assign Vertex Colors") != undefined do 
(
if (bt = windows.getChildHWND (UIAccessor.GetParentWindow win[1]) name) != undefined do UIAccessor.PressButton bt[1] 
)
)
fn bakeVertex nodes:(selection as array) channel:0 lightingModel:2 predel:on = if nodes.count > 0 do
(
bakeModi = VertexPaint name:"Bake Vertex Colors"
bakeModi.lightingModel = lightingModel
bakeModi.colorBy = 1
bakeModi.useMaps = off
bakeModi.mapChannel = channel
if getCommandPanelTaskMode() == #modify do setCommandPanelTaskMode mode:#modify
completeRedraw()
if predel do for node in nodes where isproperty node #Bake_Vertex_Colors do 
(
deletemodifier node node.Bake_Vertex_Colors
)
select nodes
modpanel.addmodtoselection bakeModi ui:on
pressAssignVColor()
)

here is a trick version… It works for me.

Thanks again Denis!

Unfortunately your solution doesn’t work either when called from a callback function, at least not after the radiosity calculation is done. Here’s the callback I added:

callbacks.addScript #radiosityProcessDone "bakeVertex()" id:#radiosityDone

When I run the code bits separately they work just fine, but as soon as bakeVertex() is called after the radiosity process is done – it causes 3ds max to hang. I tested it on 3ds max 2010 and the same happened there.