[Closed] The script can't Correctly run under the 3dsmax9

Why Appearance a smiling face’s icon
The face’s icon is “: p”
This is Correct !

(
local CheckDist=0, HitRay, ViewRay, PointDist, pointa, pointb, pointc, pointd, pt1, pt2
pt1 = pickpoint()
if classof pt1 == point3 then
(
pointA = mouse.pos
ViewRay=MapScreenToWorldRay pointA
for i in objects do
(
HitRay=intersectRay i ViewRay
if HitRay != udefined do
(
PointDist=distance HitRay.pos ViewRay.pos
if (Checkdist==0 OR Checkdist>PointDist) do
(
Checkdist=PointDist
PointC=HitRay.pos
)
)
)
pt2 = pickpoint rubberband: pt1
)
if classof pt2 == point3 then
(
CheckDist=0
pointB = mouse.pos
ViewRay=MapScreenToWorldRay pointB
for i in objects do
(
HitRay=intersectRay i ViewRay
if HitRay != udefined do
(
PointDist=distance HitRay.pos ViewRay.pos
if (CheckDist==0 OR CheckDist>PointDist) do
(
CheckDist=PointDist
PointD = HitRay.pos
)
)
)
if ((pointC != undefined) and (pointD != undefined)) then
(
Viewport.ZoomToBounds false pointC pointD
)

)
)

Hi su37,

The smiley is because those characters are automatically changed to one – just like “: )” becomes a smiley like this:

You can disable that in your post – below the “Submit Reply” there are “Additional Options”. One of the options is “Disable smilies in text”.

==========

However, even better is to place any script code within CODE and /CODE tags.

==========

Now as for your actual problem… poke at Autodesk for a bit – looks like they broke behavior… and I don’t know how to get the original behavior back either. Here are my results with fixed points:

pointC = [-20,20,40]
pointD = [-20,-20,5]
Viewport.ZoomToBounds false pointC pointD
print (viewport.getTM())

-- 3ds max 5
(matrix3 [0.707107,0.353553,-0.612372] [-0.707107,0.353553,-0.612373] [0,0.866025,0.5] [14.1421,-12.4145,-130.185])
-- 3ds max 9
(matrix3 [0.707107,0.353553,-0.612372] [-0.707107,0.353553,-0.612372] [0,0.866025,0.5] [80,-0.295036,-335.455])
-- 3ds max 2009
(matrix3 [0.707107,0.353553,-0.612372] [-0.707107,0.353553,-0.612372] [0,0.866025,0.5] [60,0.126656,-315.134])

Note that the 3ds Max 5 version zooms correctly – 9 and 2009 do not.

==========

However, here’s a work-around… it’s not as clean, but at least it works consistently in all max versions (that I’ve tested: 5, 7, 8, 9, 2008, 2009):

pointC = [-20,20,40]
pointD = [-20,-20,5]
-- disable viewports from updating
disableSceneRedraw()
-- create two small dummies at the points clicked
ppointC = Dummy boxsize:[0.01,0.01,0.01] pos:pointC
ppointD = Dummy boxsize:[0.01,0.01,0.01] pos:pointD
-- select them
select #(ppointC, ppointD)
-- call the "max zoom extents" command
max zoomext sel
-- remove the dummies
delete selection
-- enable viewports redrawing again
enableSceneRedraw()
-- hackhack: refresh just the single viewport, instead of all of them
viewport.setTM (viewport.getTM())

==========

I hope this helps

Hi ZeBoxx2,

Thank you. I understood

But my maxscript is poor. Can you help me revise the script ,let it Correctly run under the 3dsmax9 ?

thanks!

certainly – I’ve just adjusted the piece of code relevant to the problem here:

(
	local CheckDist=0, HitRay, ViewRay, PointDist, pointa, pointb, pointc, pointd, pt1, pt2
	pt1 = pickpoint()
	if classof pt1 == point3 then
	(
		pointA = mouse.pos
		ViewRay=MapScreenToWorldRay pointA
		for i in objects do
		(
			HitRay=intersectRay i ViewRay
			if HitRay != udefined do
			(
				PointDist=distance HitRay.pos ViewRay.pos
				if (Checkdist==0 OR Checkdist>PointDist) do
				(
					Checkdist=PointDist
					PointC=HitRay.pos
				)
			)
		)
		pt2 = pickpoint rubberband: pt1
	)
	if classof pt2 == point3 then
	(
		CheckDist=0
		pointB = mouse.pos
		ViewRay=MapScreenToWorldRay pointB
		for i in objects do
		(
			HitRay=intersectRay i ViewRay
			if HitRay != udefined do
			(
				PointDist=distance HitRay.pos ViewRay.pos
				if (CheckDist==0 OR CheckDist>PointDist) do
				(
					CheckDist=PointDist
					PointD = HitRay.pos
				)
			)
		)
		if ((pointC != undefined) and (pointD != undefined)) then
		(
			disableSceneRedraw()
			local ppointC = Dummy boxsize:[0.01,0.01,0.01] pos:pointC
			local ppointD = Dummy boxsize:[0.01,0.01,0.01] pos:pointD
			select #(ppointC, ppointD)
			max zoomext sel
			delete #(ppointC, ppointD)
			enableSceneRedraw()
			viewport.setTM (viewport.getTM())
--			Viewport.ZoomToBounds false pointC pointD
		)
	)
)

Extremely thanks your answer !!