[Closed] Submit to Deadline

Here it comes.
It looks scary, but half of the code is remarks, and half of the rest is the function to detect where the repository is (you can hard-code that if you want).
You can expand it by adding more SMTDSetting properties – you can see the full list of SMTD Settings by typing

show SMTDSettings

after having evaluated the SubmitMaxToDeadline_Functions.ms file.

Thanks Bobo works like a dream.

I’ve just editted the code to work from a predefined Repository location and it just submits the current open Max File. Here it is for anyone who needs it…

--Make sure the file is saved before submitting
 saveMaxFile quiet:true
 
 	(
 		global SMTDSettings  --this is the global variable that will contain the submission settings of SMTD
 		global SMTDFunctions --this is the global variable that will contain the submission functions of SMTD
 		
 		local theNetworkRoot = "" --this variable will hold the network root path - the path to the Repository
 		local theHomeRoot = "" --this variable will hold the local home folder of Deadline
 	
 
 		--------------------------------------
 		--MAIN SUBMISSION CODE
 		--------------------------------------
 			theNetworkRoot = "\\\\deadline.yourserver.com\\DeadlineRepository" --and we assign the network root value to our variable for later use.
 			format "Network Root is '%'
" theNetworkRoot 
 						
 			--First, we load the script file with the function definitions
 			local remoteScript = theNetworkRoot + "\\submission\\3dsmax\\SubmitMaxToDeadline_Functions.ms"  --this is the file name on the Repository
 			local localScript = getDir #scripts + "\\SubmitMaxToDeadline_Functions.ms" --to speed things up, we will copy it locally first, then we will load it
 			if doesFileExist remoteScript then --if the remote file exists,
 			(
 				deleteFile localScript --we delete the local file in case it exists already
 				copyFile remoteScript localScript --then we copy the remote file over
 				fileIn localScript quiet:true --and execute it (equivalent to Main Menu > MAXScript > Run Script...)
 				
 				--At this point, SMTDFunctions should have been initialized to the latest version found on the Repository.
 				--Now we have to make sure all defaults (both global and local) are loaded, otherwise the SMTDSettings struct would contain factory defaults
 				SMTDFunctions.loadSettings()
 														
 				---### use currently open file
 				f = maxfilepath + maxfilename
 				
 				SMTDSettings.JobName = getFileNameFile f + " [BATCH SUBMISSION BETA]" --we could for example set the job name to the name of the max file and any custom text we want
 				SMTDSettings.Comment = "Submitted from the batch Custom Submitter" --we could set the comment field
 				SMTDSettings.Priority = 50 --we can override the priority, for example we could increment the priority based on the order of the files or something else
 	
 				--Note that the simple act of loading SMTDFunctions has also initialized a SMTDPaths struct with default paths - type 'show SMTDPaths' to see what paths are available
 				local SubmitInfoFilename = SMTDPaths.tempdir + "\\max_submit_info.job"  --we define the submit info file name which will contain info about the submission settings
 				local JobInfoFilename = SMTDPaths.tempdir  + "\\max_job_info.job" --and the job info file which will contain info about the job's settings (most of them can be changed in the job's Properties dialog of the Monitor
 	
 				SMTDFunctions.CreateSubmitInfoFile SubmitInfoFilename --we then call the function to create a submit info file based on the current SMTDSettings values
 				
 				--We also call the function to create a job info file. It will contain all info about the current scene like renderer settings, list of cameras etc.
 				--This function accepts optional overrides for the render output filename, the tiles to render and the camera to render. 
 				--We can specify these if we know them: renderOutputOverride:"" tileString:"" forceCamera:"" 
 				SMTDFunctions.CreateJobInfoFile JobInfoFilename  --renderOutputOverride: could be set to a string that points at the network location to write the images from the scene being submitted instead of using the renderer's output settings!
 					
 				--Now that we have all the files we need for a submission (the scene file, the submit info and the job info file), we can call the submitter!
 				--To do this, we will have to create an argument list to pass to DeadlineCommandBG
 				local initialArgs = "\"" + SubmitInfoFilename + "\" \"" + JobInfoFilename  + "\" \"" + f + "\" " 
 				
 				--We call the DeadlineCommandBG with our arguments and the timeout (which you can customize)
 				local retcode = SMTDFunctions.waitForCommandToComplete initialArgs SMTDSettings.TimeoutSubmission
 				
 				--Once the command returns, we can try to get the message from the message file. Even if it failed, the file could contain userul error info...
 				local renderMsg = SMTDFunctions.getRenderMessage() 
 				SMTDFunctions.getJobIDFromMessage renderMsg --we can also extract the job ID from the render message - it will be stored in SMTDSettings.DeadlineSubmissionLastJobID
 				
 				if retCode == #success then --if the return code from the call was #success, we show a positive message
 				(
 					format "File % submitted successfully as Job %.

%

" (filenameFromPath f) SMTDSettings.DeadlineSubmissionLastJobID renderMsg
 					SMTDFunctions.CopyExternalFilesToRepository() --copy files to main job
 				)	
 				else --if the code was anything else, we print the message as error message
 					format "Remaining Frames Job Submission FAILED.

%" renderMsg 
 						
 		)--end if root resolved
 	)--end script

–Alternatively, we could submit the file without opening it, but then we would have to provide a custom job info file without real insight into the file’s content, which can be tricky, but a lot faster to execute

Bobo, what info do we get from opening the file, if say I had 10 files I wanted to be submitted to Deadline, all very similar, could it be possible to get the info required from just opening one file and then submitting all the others based on this? Would be much much quicker if we didn’t have to wait for each pass to submit individually, and just let it batch submit once all passes were setup without opening each one.

rgds

Dave

Dave,
How about selecting all the Max files you want to batch submit in the deadline monitor via the “Submit 3dsMax Job to Deadline” py script? This py submission script handles multiple Max files and provides some basic functionality which is generic between scene files. You could execute the py code directly from within Max using Blur’s python wrapper if this is necessary.
Mike