[Closed] Scripted Geometry – reference problem

first of all i don’t think that simpleObject is the right type of plugin for this task… more likely it should be a modifier … the simpleMeshMod

but of course we can organize true monitoring of any mesh with simpleObject plugin…

Hello again,

I did it with the modifier (i also did it with function -> reference copy and mirror modifier) but you have to do one or more clicks (that is one of the reasons i went to the geometry, the other is learning references). I finaly made it work but without the weak reference. I would be very interested and much appreciated if someone could give some ideas about how to get notification from a weak referenced node about its mesh changes.
Here is the code of the updated version (the pickbutton .text still is not being stored, even though i used a parameter):

plugin simpleObject MirrorObject
name:"Mirror Object"
classID:#(0x14c6b999, 0x6c060ea1)
category:"har1sf0x"
(
   parameters mainP rollout:mainR
   (
      valid type:#boolean default:false
      mirrorBool type:#boolean default:true ui:chk_mirror
      obj type:#node--#maxObject
      txt type:#string
--       on obj set val do this.rebuildMesh()
--       on mirrorBool set val do this.rebuildMesh()
   )
   rollout mainR "Parameters"
   (
      pickbutton pck_obj "Pick mesh" autodisplay:true
      checkbox chk_mirror "Mirror" checked:true
      on pck_obj picked o do
      (
         if isValidnode o and superclassof o == GeometryClass do
         (
            obj = o--(nodeTransformMonitor node:o forwardTransformChangeMsgs:false)
            txt = o.name
            pck_obj.text = txt
            valid = true
         )
      )
--       on mainR open do (if valid and isValidNode obj do (pck_obj.text = obj.name))--;mirrorBool = chk_mirror.checked)
   )
   
   on buildmesh do this.rebuildMesh()
   
   fn rebuildMesh =
   (
      proxy = trimesh()
      setMesh proxy length:10 width:10
      if valid and isValidNode obj do--.node do
      (
         proxy = obj.mesh--.node.mesh
         if mirrorBool do proxy = this.mirrorMesh proxy
      )
      setMesh mesh proxy
   )
   fn mirrorMesh msh =
   (
      for f =1 to msh.numFaces do
      (
         verts = getFace msh f
         local tmp = verts.x
         verts.x = verts.z
         verts.z = tmp
         setFace msh f verts
      )
      for v = 1 to msh.numVerts do
      (
         setVert msh v ((getVert msh v)*[-1,1,1])
      )
      update msh
      msh
   )
   
   tool create
   (
      on mousePoint click do
      (
         case click of
         (
            1: nodeTM.translation = gridPoint
            2: #stop
         )
      )
   )
)

Best regards,
har1sf0x

You just have to change two lines in your code:

.
.
      txt type:#string default:"Pick mesh"
.
.
      pickbutton pck_obj txt autodisplay:true
.
.

But, in fact, I can’t understand how your plugin works (and it works fine). I mean, why the MirrorObject changes when you change the referenced node. I can’t see any handler for this.

What is your goal? I mean, what are you missing in your plugin?

#1 try to use nodemonitor instead of nodetransformmonitor
#2 look at referencetargetcontainer

see this example that i’ve showed here and on area…

plugin simpleObject Cloner
   name:"Cloner"
   classID:#(0x00001967, 0x0af62091)
   category:"Scripted Primitives"
   silentErrors:off
   version:1
(
   fn validGeometry node = (iskindof node GeometryClass) 
--   local mesh
   parameters main rollout:main 
   (
      meshTarget type:#node subanim:on ui:pickobject_bt
      meshObject type:#MaxObject
   )
   parameters params rollout:main 
   (
      count type:#integer ui:ui_count
      radius type:#worldunits ui:ui_radius
      tilt type:#worldunits ui:ui_tilt
   )
   rollout main "Parameters"
   (
      group "Mesh Object: "
      (
         pickbutton pickobject_bt "Pick Mesh Object" autoDisplay:on filter:validGeometry width:144 align:#right offset:[4,0] 
      )
      on pickobject_bt picked obj do
      (
         meshObject = createinstance Editable_mesh
         meshObject.mesh = obj.mesh
      )
      
      group "Spacing: "
      (
         spinner ui_count "Count: " range:[1,512,1] type:#integer fieldwidth:60 align:#right offset:[4,0] 
         spinner ui_radius "Radius: " range:[0,1e9,0] type:#worldunits fieldwidth:60 align:#right offset:[4,0] 
         spinner ui_tilt "Tilt: " range:[0,1e9,0] type:#float fieldwidth:60 align:#right offset:[4,0] 
      )
   )
   fn _transformMesh mesh tm = 
   (
      list = for v=1 to mesh.numverts collect ((getVert mesh v)*tm)
      setmesh mesh vertices:list
   )
   fn _attachMeshes meshes = 
   (
      n = meshes.count
      while (num = n/2) > 0 do for k=1 to num do 
      (
         meshop.attach meshes[k] meshes[n]
         n -= 1
      )
      meshes[1]
   )
   on buildMesh do
   (
      setMesh mesh numverts:0 numfaces:0
      if meshObject != undefined do
      (
         m = if isvalidnode meshTarget then (copy meshTarget.mesh) else (copy meshObject.mesh)
         tm = transmatrix [radius,0,0]
         cc = for k=1 to count collect
         (
            c = copy m
            _transformMesh c tm
            tm = prerotateY tm (tilt/count)
            tm = rotateZ tm (360.0/count)
            c
         )
         setMesh mesh (_attachMeshes cc)
         
         free m
      )
   )
   tool create
   (
      on mousePoint click do case click of
      (
         1: 
         (
            nodeTM.translation = gridPoint
            #stop
         )
      )
      on mouseMove click do case click of
      (
      )
   )
)

you can use NodeTransformMonitor instead of node…
also there is another way of to store mesh (using reftargcontainer). you can find posts about it on this forum

Hello and thank you for your concern.

I’ve read your post in the autodesk forum and just tested but it also creates a dependency loop becauce of the meshTarget. That is what makes the mesh update live. If you comment the

ui:pickobject_bt

in line 12 the object will not give a dependency loop but it will also not update live.
I tend to believe that it is not possible to create a ‘live’ reference to an other object without creating a dependency loop. I even tried to create and test an indirect reference (ref.setIndirectReference() getting error all over the place) but as i saw in the help files it cannot be done via maxscript.

p.s. have in mind that your script was crashing in my computer probably because of count=0 on initialization even thougn in the ui was saying 1 (because of the range) and the cc was an empty array. i gave a default to count and worked like a charm.

p.s.1 as i said i tested the other suggestions. i do not want to store the mesh. i want to reference it so as to update live

p.s.2 when you create a reference copy of an object it does not create a dependency loop and updates the mesh live. that is what i am looking for to replicate in my plugin.

yes … my example crashes if the number of cloned instances equals 0. but believe me i don’t care. usually my example codes are very far from my commercial versions. but they show enough…

going to your issue…

i see a fundamental misunderstanding of how the notification system works. because of the difference there are special ways (plugin types) to achieve what you want.