[Closed] Replace "Render button/max quick render" sequence with custom function?

I’ve tried several different workarounds for this, all of them either giving me the same error as this one, or

– Runtime error: Unable to open renderer, possible recursion <<

Can anyone tell me if there is any way to do this???

I’d hoped this might be a possible workaround, but unfortunately it still returns an unidentified error.

global wasRender = false
dialogMonitorOps.unregisterNotification id:#test
dialogMonitorOps.enabled = false

fn check = (
	if wasRender then (
		render()
		wasRender = false
	)
	else (
		local hwnd = dialogMonitorOps.getWindowHandle()
		local hwndText = uiAccessor.getWindowText hwnd		

		if classOf hwndText == string do (
			local substr = substring hwndText 1 9

			if substr == "Rendering" do (
				uiAccessor.pressButtonByName hwnd "Cancel"
				wasRender = true
			)
		)	
	)

	return true
)

dialogMonitorOps.registerNotification check id:#test
dialogMonitorOps.enabled = true

Well, it’s ugly, but it will get the job done until something better comes along.

rollout RO_Delay "Preparing Render" (
  timer clock "testClock" interval:1000

  on clock tick do (
    render()
    destroyDialog RO_Delay
  )
)


dialogMonitorOps.unregisterNotification id:#test
dialogMonitorOps.enabled = false

fn check = (
	local hwnd = dialogMonitorOps.getWindowHandle()
	local hwndText = uiAccessor.getWindowText hwnd		

	if classOf hwndText == string do (
		local substr = substring hwndText 1 9

		if substr == "Rendering" do (
			uiAccessor.pressButtonByName hwnd "Cancel"
			createDialog RO_Delay
		)
	)

	return true
)

dialogMonitorOps.registerNotification check id:#test
dialogMonitorOps.enabled = true

http://forums.cgsociety.org/showthread.php?f=98&t=1434925

Feel free to take a crack at it if you like. I’ve thrown all the time at it that I’m going to, and have been told by more experienced people than myself that it can’t be done.

how is about just make several instances of the same light with all available shadow generators. And turn them ON/OFF using a parameter (instead of reassign a new generator).

In this case it will be truly animatable and renderable for every built-in renderer

6th post down that was what I was trying to do actually, but I couldn’t figure out how to make it work right.

here is a setup that doesn’t need any callbacks to work:

ca_sg = attributes ca_sg attribID:#(111,222)
(
	fn update = 
	(
		if iskindof this.light RefTargMonitor do
		(
			format "% > %
" currenttime this.current
			this.light.refTarg.shadowGenerator = this.shadowGenerator
			1
		)
		0
	)
	parameters params
	(
		light type:#maxobject
		current type:#integer default:1 animatable:on 
		shadowGenerators type:#maxobjecttab tabsize:3
		shadowGenerator type:#maxObject 
		
		on shadowGenerator get val do
		(
			val = shadowGenerators[current]
		)
	)
)

delete objects
d = dummy()
custattributes.add d ca_sg
d.ca_sg.shadowGenerators = #(Area_Shadows(), ShadowMap(), RayTraceShadow())
	
	
lit = omnilight()
d.ca_sg.light = RefTargMonitor refTarg:lit

c = d.scale.controller = scale_script()
c.addobject "owner" (RefTargMonitor refTarg:d.ca_sg)
	
c.setexpression "owner.reftarg.update(); [1,1,1]"	

at time 0 animate on d.current = 1
at time 10 animate on d.current = 2
at time 20 animate on d.current = 3	
	
--lit.shadowGenerator

but it doesn’t solve your problem.

the ‘shadowGenerator’ parameter is not animatable. It’s being taken once works for whole rendering session. There is no way to change it on the fly

I’d considered it, but I’d rather have it run invisibly. This way people can use what they’re used to and start it from the same dialog where they set all the parameters. Besides, Max’s built-in render can be accessed so many different ways, and I was annoyed by the way it handles non-animatable parameters.

Also, it’s been an opportunity to learn some pretty interesting things.

So now the only thing I need to figure out how to implement is the “Current Task” progress bar as shown in the rendering dialog (i.e. Transforming Vertices/Rendering Image).

Unfortunately I’m not really sure where those values actually come from. Any tips on where I might be able to find this information?