[Closed] Remove selected objects that are not actually visible in the current view

disable textures, switch viewport shading to flat, get viewport bitmap and check pixel by pixel which wirecolors are visible. simple as that
of course it requires that objects have unique wirecolors

Wow, the creativity of you and a few others in here never seizes to amaze me, that’s a really clever idea. You don’t happen to know if something like this has been posted in here before? Or maybe something similar that I could use as reference when trying to write this script myself?

there certainly were scripts posted that separately solve parts of the task, but it is likely that you will faster code it yourself than find something with forum search broken
You’ll have to make sure to disable safe frames, stats, make viewport background flat-colored etc… in order this workaround to actually work.

I am currently working on a script which does exactly the same. Will be released as soon as possible.
Short video: https://drive.google.com/file/d/1mXedFqmaffEU-60MpXVdNqGxtI-tVAsn/view?usp=sharing

Oh, awesome! I’m curious, are you using the pixel method, or have you been able to figure out another method? The reason I ask is that I did some tinkering with the pixel method, and it kinda works, but it wasn’t completely accurate. I guess I would have to increase the resolution to increase the accuracy, but that would mean I would have to render the current view.

I am using few methods.
Here is another video. Almost everything that I need is already added:
https://drive.google.com/file/d/16S5hnyJNtE3xSMYZrTkCEUI3aeskVIs9/view?usp=sharing

It looks awesome, really excited to test it when you’re finished. I have to say, you amongst a few others in here have contributed and helped so many people, thank you!

this sort of thing works after a “fashion”

   fn getScreenBounds obj =
    (
    	maxy = maxx = -99999999.0;
    	miny = minx = 99999999.0;
    	
    	gw.setTransform(Matrix3 1);
    	
    	msh = snapshotasmesh obj;
    	for v = 1 to msh.numverts  do
    	(
    		spos = gw.wTransPoint (getvert msh v);
    		if spos.x > maxx then maxx = spos.x;
    		if spos.x < minx then minx = spos.x;	
    		if spos.y > maxy then maxy = spos.y;
    		if spos.y < miny then miny = spos.y;	
    	)
    	delete msh;
    	
    	Box2 minx miny (maxx - minx + 1) (maxy - miny + 1)
    )

    fn boxinbox b1 b2 =
    (
    	return contains b1 [b2.left, b2.top] and contains b1 [b2.right, b2.top] and contains b1 [b2.right, b2.bottom] and
    				contains b1 [b2.left, b2.bottom];
    )	

    fn IsObscured node1 node2 camera_pos =
    (
    	msh = snapshotasmesh node2;
    	
    	obscured = true;
    	for v = 1 to msh.numverts while obscured do
    	(
    		pos = getvert msh v;
    		dir = camera_pos - pos;
    		
    		if intersectray node1 (ray pos dir) == undefined then obscured = false;
    	)
    	
    	delete msh;
    	obscured;
    )	

    fn comp_node_depth v1 v2 =
    (
    	x1 = v1[2].x;
    	x2 = v2[2].x;

    	if x1 == x2 then 0 else if x1 > x2 then -1 else 1;
    )	

    fn getNodesInDepthOrder tm =
    (
    	nodes = for obj in objects collect #(obj, obj.pos * tm, getScreenBounds obj);	
    	qsort nodes comp_node_depth; 
    	nodes	
    )	

    fn hide_obscured =
    (
    	ivptm = inverse (getViewTM());
    	
    	nodes = getNodesInDepthOrder ivptm;
    	
    	for n = 1 to nodes.count - 1 do
    	(
    		unhide 	nodes[n][1];
    		
    		obscured = false
    		for nn = n + 1 to nodes.count while not obscured do
    		(
    			if boxinbox nodes[nn][3] nodes[n][3] then
    				obscured = IsObscured nodes[nn][1] nodes[n][1] ivptm[4];
    		)
    		if obscured then hide nodes[n][1];
    	)
    )	


    UnRegisterRedrawViewsCallback hide_obscured
    RegisterRedrawViewsCallback hide_obscured

This line

should be

pos = getvert msh v;

or a msh2 variable has to be used?

With this the script works fine: pos = getvert msh v;