[Closed] Mini Challenge: incremental unique Filenames

Based on the same code, something a bit smarter:

fn getXRefSceneFilename =
(
	baseXRef = getMAXSaveFileName filename:"*.max" -- User File select. Weird as the function ask "do you want to replace it?"
	exportFilename = undefined
	
	if baseXRef != undefined do
	(
		baseName = getFilenameFile baseXRef
		basePathName = getFilenamePath baseXRef
		trimBaseName = trimRight baseName "1234567890"
		
		sameBaseName = getFiles (basePathName+trimBaseName+"*.max") -- Get files with same base name
		newIndex = 0
		
		if sameBaseName.count != 0 then -- Case the user selects an existing file
		(
			fileIndex = for f in sameBaseName where	-- Avoid filenames starting equal but that are different
			(
				tempBaseName = getFilenameFile f
				tempTrimBaseName = trimRight tempBaseName "1234567890"
				check = tempTrimBaseName.count == trimBaseName.count 
			)
			collect
			(
				index = (substring tempBaseName (tempTrimBaseName.count+1)  -1) as integer
			)
			
			newIndex = (amax fileIndex) +1
		)
		else -- Case the user writes a new filename
		(
			newIndex = 1
		)
		
		-- Convert maximum index to formatted string of 3 digits
		stringIndex = newIndex as String
		if stringIndex.count == 1 then stringIndex = "00"+stringIndex else if stringIndex.count == 2 then stringIndex = "0"+stringIndex
		
		exportFilename = basePathName + trimBaseName + stringIndex + ".max"
	)
	
	exportFilename
)

You could use getMAXOpenFileName() instead to avoid the confirmation dialog.

You can simplify it by using formattedPrint()

stringIndex = formattedPrint newIndex format:"03d"

i have’t really been care about optimization and ‘purity’ of the mxs using writing this code.
so here is a .net-based mxs structure which can be easily extended to fit your needs:

global XRefFileSupport
(	
	struct XRefFileStruct
	(
	private
		dotnetstring = dotnetclass "System.String",
		dotnetpath = dotnetclass "System.IO.Path",
		dotnetdir = dotnetclass "System.IO.Directory",
		dotnetfile = dotnetclass "System.IO.File",
		dotregex = dotnetobject "System.Text.RegularExpressions.Regex" @"(\d+)$",
	public
		FileStruct =
		(
			struct FileStruct (file, path, name, base, id, type)
		),
		fn sortByID s1 s2 = (s1.id - s2.id),
		fn parseFilename filename = 
		(
			path = dotnetpath.GetDirectoryName filename
			name = dotnetpath.GetFileNameWithoutExtension filename
			type = dotnetpath.GetExtension filename
			
			ss = dotregex.Split name
			base = ss[1]
			id = if ss.count > 2 then ss[2] as integer else 0

			FileStruct file:filename path:path name:name base:base id:id type:type
		),
		fn buildFilename file = 
		(
			f = dotnetstring.Format "{0}\\{1}{2:d3}" file.path file.base file.id
			dotnetstring.Format "{0}{1}" f file.type -- in case you want to do anything special with extension
		),
		fn makeMask file = 
		(
			dotnetstring.Format "{0}*{1}" file.base file.type
		),
		fn findFilesAs file sorted:on =
		(
			mask = makeMask file
			files = dotnetdir.GetFiles file.path mask
			files = for f in files collect (parseFilename f)
			if sorted do qsort files sortByID
			files		
		),
		fn getAvailableIndex data = 
		(
			ids = (for f in data collect (f.id + 1)) as bitarray
			id = 1
			while ids[id] and id <= ids.count do id += 1
			id-1
		),
		fn getNextFile file increment:on = 
		(
			filesas = findFilesAs file
			_file = copy file
			if increment then
			(
				_file.id = filesas[filesas.count].id + 1
			)
			else
			(
				_file.id = getAvailableIndex filesas
			)
			buildFilename _file
		),
		fn getAllFiles path =
		(
			files = dotnetdir.GetFiles path
			for f in files collect (parseFilename f)
		)
	)
	XRefFileSupport = XRefFileStruct()
	ok
) 

using could be:

all = XRefFileSupport.getallfiles @"C:\Temp\"
ff = XRefFileSupport.findfilesas all[2]
XRefFileSupport.getnextfile ff[1] --increment:off 

PS. you are free to extend my code as well as fix bugs

1. Buy the way, I’ve met such situations when a missing file with LOWER CASE extension (jpg, ies…) could be found in a folder, but but with UPPER CASE extension, and even after repathing I had missing for such files

2. getallfiles – doesn’t give the posibility to use ProgressBar for searching.