[Closed] Maximizing another process from MXS

You can find examples of how to determin if 3dsmax is running. find the proper thread(it was a thread of how to kill 3dsmax.exe in taskmanager).
There are examples of how to minimize/maximize the Edit UVWs editor window.

Thanks!

     DOScommand ended up being a dead end, mostly because it apparently can't return anything useful...
     
     Seems I can minimize or maximize an app via "windows.SendMessage" (no idea about setting active / highest in windows z-order) so long as I have the windows handle (hWnd). Problem is the only way I know how to get that is via "windows.getchildhwnd", and that gets the hWnd using the title bar name instead of the process file name, which isn't very useful with programs that list their (constantly changing) version number on the title bar.
     
     So, anyone knows of a way to get the hWnd of a running process via the process name (ie. notepad.exe , photoshop.exe , etc.) ?

system.diagnostics.process.getprocesses()
Find the process you need (by name, wildcard, whatever)
Process.MainWindowHandle

Thanks Denis, but I’m not really getting anything out of that method?

dotnetclass “System.Diagnostics.Process.GetProcesses()” always returns undefined.

If I use:
(dotnetclass “System.Diagnostics.Process”).GetProcessesByName “notepad”
the number of array items returned will be correct, but the actual contents are all the same string, that is:
#(dotNetObject:System.Diagnostics.Process)
So if I have several instances of the app running the returned array looks like this:
#(dotNetObject:System.Diagnostics.Process, dotNetObject:System.Diagnostics.Process, dotNetObject:System.Diagnostics.Process, dotNetObject:System.Diagnostics.Process)

This is actually my first time using .NET , so I’m probably just missing something basic.

thanks. you’ve showed that the thing works

pp = (dotnetclass "System.Diagnostics.Process").GetProcesses()
showproperties pp[1] -- if there is any
pp[1].mainwindowhandle ---->?

using getprocessesbyname you have give exact name. my idea is to collect all processes and try to find one you need by matching a pattern.

Here is a simple function. You can customize it to fit your needs.

(
 	
 	fn BringWindowToFront pName =
 	(
 		/* Get all running Processes */
 		processes = (dotnetclass "System.Diagnostics.Process").GetProcesses()
 		
 		/*
 			Find the one that matches the given name.
 			In this example it needs to be the EXACT same name,
 			but you can change it to work with wildcards.
 		*/
 		handles = for j in processes where j.ProcessName == pName collect j.MainWindowHandle
 			
 		/*
 			More than one Process with the same name.
 			You'll need another property to bring the correct one to the foreground
 		*/
 		if handles.count > 1 do return messagebox "More than one Process with the same name found."
 		
 		/* No Process found. Display an Alert */
 		if handles.count == 0 do return messagebox ("Process not found.
\"" + pName +"\"")
 			
 		/*
 			We got a matching Process. Bring it to the front.
 			There are several ways of doing this. This is the simplest I know.
 		*/
 		local WM_SYSCOMMAND = 0x0112
 		local SC_RESTORE = 0xF120
 		windows.sendmessage handles[1] WM_SYSCOMMAND SC_RESTORE 0
 	)
 
 	BringWindowToFront "notepad"
 	
 )

Thanks guys, problem solved

One small note in case anyone else wants to use this method to switch apps in the future: SC_RESTORE wont make the other app active unless it’s coming from a minimized state, so you need to run SC_MINIMIZE first just to be sure. ie.

windows.sendmessage handles[1] WM_SYSCOMMAND SC_MINIMIZE 0
windows.sendmessage handles[1] WM_SYSCOMMAND SC_RESTORE 0

it would be better to activate the window and probably send it on top.
(there is no max around to provide a working code. sorry)