[Closed] Make planar spline verts?

this is not a problem… just needs to know the plane parameters. but the question is – what do you want to do with in and out tangents? simply project them to the same plane?

Took this from the help. It was wrapped up in extra coolness that made it “not work”. Rather than figure out how to make it work (ongoing annoyance with maxscript, the various contexts code can not run in) I stripped stuff out. Seems to work for some simple test cases. Drag and drop from script editor to a button.

new_z = $.pos.z
for s = 1 to (numSplines $) do
(
for k = 1 to (numKnots $ s) do
(
knt = getKnotPoint $ s k
in_vec = getInVec $ s k
out_vec = getOutVec $ s k
knt.z = in_vec.z = out_vec.z = new_z
setInVec $ s k in_vec
setOutVec $ s k out_vec
setKnotPoint $ s k knt
)–end k loop
)–end s loop
updateshape $

hey guys, thanks for the replies, very happy to see its doable.

as far as the tangents, i just need the planar for the default ‘corner’ tangent, then once aligned i’ll change the tangent types.

gruhn:

it works, but it flattens the whole spline,

what i was looking for was selecting to points on a spline, and say im in Top view, wanting the two points (out of a spline with 10 points) to be lined up in a specific axis, such as Y.

so the other points wouldn’t be affected, regardless of their world position. instead of making the entire spline planar.

edit: i forgot to mention that it does not seem that you can ‘undo’ your script operation. not a big deal really, just thought i’d throw that in there

thanks for the help

bumpity bump

would pay for a script that could do this, 20 bones to u if u build it they will come.

http://remusjuncu.com/phone/files/planarKnots.mse

done… but it will close the dialog after each run :wavey:

@denisT
😮 $800 :bounce:

$40 usd to u to not close dialog and you keep script to sell

@denisT
😮 $800 :bounce:

it was a joke. but… do you add to the price all months when you learn max scripting?

and… forgot to say. i would never pay for an encrypted tool at all.

what is the reason to hide the code if it doesn’t make you money anyway?

try(destroydialog planarPoints) catch()
 rollout planarPoints "Planar Points by denisT" width:200
 (
 	radiobuttons type_rb "Projection Axis:" labels:#("X", "Y", "Z", "View") default:3 columns:4 align:#left offset:[0,-3]
 	checkbox selected_ch "Selected Points" checked:off offset:[0,4]
 	checkbox tangents_ch "Include Tangents" checked:on offset:[0,0]
 	checkbox average_ch "Average Position" checked:on
 	button planar_bt "Planar" width:190 offset:[0,4]
 	
 	fn makePlane pos:[0,0,0] = 
 	(
 		case type_rb.state of 
 		(
 			0: ray pos x_axis
 			1: ray pos y_axis
 			2: ray pos z_axis
 			4: ray pos (normalize (inverse (getViewTM()))[3])
 	  default: ray pos z_axis
 		)
 	)
 	
 	fn averageShapePointPos sp selected:off = if iskindof sp SplineShape do
 	(
 		pos = [0,0,0]
 		count = 0
 		for c=1 to numsplines sp do
 		(
 			knots = if selected then getKnotSelection sp c else #{1..numknots sp c} as array
 			count += knots.count
 			for k in knots do pos += getKnotPoint sp c k
 		)
 		pos/count
 	)
 	mapped fn planarShapePoints sp includeTangents:on selected:off planeAxis:(ray [0,0,0] [0,0,1]) = if iskindof sp SplineShape do
 	(
 		fn planar p tm = 
 		(
 			p *= inverse tm
 			p.z = 0
 			p * tm
 		)
 		converttosplineshape sp
 		tm = translate (matrixfromnormal planeAxis.dir) planeAxis.pos
 		for c=1 to numsplines sp do
 		(
 			knots = if selected then getKnotSelection sp c else #{1..numknots sp c} as array
 			for k in knots do
 			(
 				setKnotPoint sp c k (planar (getKnotPoint sp c k) tm)
 				if includeTangents do
 				(
 					setInVec sp c k (planar (getInVec sp c k) tm)
 					setOutVec sp c k (planar (getOutVec sp c k) tm)
 				)
 			)
 		)
 		updateshape sp
 	)
 	on planar_bt pressed do undo "Planar Knots" on 
 	(
 		sps = for node in getCurrentSelection() where iskindof node SplineShape collect node
 		if sps.count > 0 do
 		(
 			suspendediting()
 			pos = [0,0,0]
 			
 			if average_ch.state do
 			(
 				for sp in sps do pos += averageShapePointPos sp selected:selected_ch.state
 				pos/sps.count
 			)
 			axis = makePlane pos:pos
 			planarShapePoints sps includeTangents:tangents_ch.state selected:selected_ch.state planeAxis:axis
 			resumeediting()
 		)
 	)
 )
 createdialog planarPoints

well, at least i get a happy ending after all the drama,

rappy i bought your rappatools, pm if you not happy with that, will work something more out