[Closed] MS + DotNet MultiThreading with objects creation

Well thank’s DenisT, i’ll try something else

I can be done indirectly… but you’ll loose any advantages of multi threading and it’s not very efficient but for small things it works great.

If you create a global array onto which you can push strings of maxscript from your backgroundworker thread you can execute those strings in the main thread via a execute command in dotnet timer like so:

 script_queue=#()
 
 fn scanScript = (
 
 	if (script_queue.count>0) do
 	(
 		scr=script_queue[1];
 		deleteItem script_queue 1
 		try(
 			execute scr[1]
 		) catch
 		(
 			print "**MXS ERROR**"
 		)
 	)
 )

scriptExecuter = dotNetObject "System.Windows.Forms.Timer"
 dotnet.addEventHandler scriptExecuter "tick" scanScript
scriptExecuter.interval = 100
scriptExecuter.start()
 

Thank you Jonadb, your solution seems to be for heavy calculation beside little maxscript viewport operation, is it ?

In fact my script run through all the vertex of an object ( and through the timeline) and it create a plane on each vertex ( with normal orientation), then i add on each modifiers and finally at the end of the frame it convert all the separate plane into a single edit poly. Then next frame is started.

I was thinking about cutting the timeline and then calling through DotNet 8 times 3ds max (1 per thread) and running the script, and finally regrouping the resulting geometry inside the same max.

Ok, thank you for the tips about the proboolean works great !

I keep searching about launching other 3ds max, opening the same scene , starting the same script but with other frame to perform.

Ps : I don’t get if you pass through TCP/IP to start things on the same computer or if you use it to start things through network

It’s a secret method But you can see them UI for ProBoolean, just count the radio button starting at 0, somehow 4 and 5 aren’t listen in the docs.

0=Union
1=Intersection
2=Subtraction
3=Merge
4=Attach <= this is what we want
5=Insert

Very nice. I did not know about that.
And how can I perform this “attach” method in this example if is not a secret

 delete objects
 shift = on
 tea = teapot radius:10 name:"main"
 for z = 0 to 9 do 
 (
 	shift = not shift
 	for x = 0 to 9 do 
 	(
 		main = (copy $main)
 		main.pos = if shift then [30*x,0,20*z] else [10+30*x,0,20*z]
 		in coordsys local main.rotation =  (random (eulerAngles 0 0 0) (eulerAngles 0 0 359))
 		main.wirecolor = (clr = random black white ; clr.s = 255. ; clr)
 	)
 )
 delete $main
 ProBoolean.SetOperandA $.main001
 -- . . . ???
 

Like so:

delete objects
 shift = on
 teamain = teapot radius:10 name:"teamain"
 
 ProBoolean.createBooleanObject  $teamain undefined 4 1 0   --create master boolean with no operant B (undefined)
 
 tea = teapot radius:10 name:"sub"
  
 for z = 0 to 9 do 
 (
	 shift = not shift
	 for x = 0 to 9 do 
	 (
		 sub = (copy $sub)
		 sub.pos = if shift then [30*x,0,20*z] else [10+30*x,0,20*z]
		 in coordsys local sub.rotation =  (random (eulerAngles 0 0 0) (eulerAngles 0 0 359))
		 sub.wirecolor = (clr = random black white ; clr.s = 255. ; clr)
		ProBoolean.SetOperandB $teamain sub 4 0   -- keep adding B operands
	)
 )

Hey Jonathan,
your attach method is very fast!
This is the test on the Teapot Wall
#1 TEST

 (
 delete objects
 shift = off
 geo = Editable_Mesh transform:(matrix3 1) wirecolor:yellow name:"teamain"	
 ProBoolean.createBooleanObject  $teamain undefined 4 1 0   --create master boolean with no operant B (undefined)
 tea = teapot radius:10 name:"sub"
 gc()
 t1 = timestamp()
 m1 = heapfree	
 for z = 0 to 19 do 
 (
 	shift = not shift
 	for x = 0 to 19 do 
 	(
 		sub = (copy $sub)
 		sub.pos = if shift then [30*x,0,20*z] else [10+30*x,0,20*z]
 		in coordsys local sub.rotation =  (random (eulerAngles 0 0 0) (eulerAngles 0 0 359))
 		ProBoolean.SetOperandB $teamain sub 4 0   -- keep adding B operands
 	)
 )
 delete $sub
 format "time:% memory:%
" ((timestamp()- t1 as float)/1000) (m1-heapfree)
 )
 

The result > time:0.328 memory:224184L

#2 TEST

 (
 delete objects
 shift = off
 geo = Editable_Mesh transform:(matrix3 1) wirecolor:yellow name:"teamain"	
 tea = teapot radius:10 name:"sub"
 gc()
 t1 = timestamp()
 m1 = heapfree	
 for z = 0 to 19 do 
 (
 	shift = not shift
 	for x = 0 to 19 do 
 	(
 		sub = (copy $sub)
 		sub.pos = if shift then [30*x,0,20*z] else [10+30*x,0,20*z]
 		in coordsys local sub.rotation =  (random (eulerAngles 0 0 0) (eulerAngles 0 0 359))
 		attach geo sub
 	)
 )
 delete $sub
 format "time:% memory:%
" ((timestamp()- t1 as float)/1000) (m1-heapfree)
 )
 

The result > time:24.684 memory:224184L

Huge difference in speed.
Thanks again for this example.

Yeah I know