[Closed] Lambdas in Maxscript – First Attempt

Ok, found a solution for the missing overloading of functions.
I forgot that i can use the struct initializing to get the parameters.

Also the code should now work. So ignore the solution above.

Only thing i am still missing is a way to use named arguments in function calls inside lambda

 
-- test calls some with 1 parameter and some with 2 parameter
CheckAge p1 \
	isNotAlive:	(lambda print "you arent't even alive, c'mon man!")\	
	isAdult:		(lambda PrintGreeting "welcome" p1)\				
	isChild:		(lambda print "is child")	
	
-- test lambda inside of lambda
CheckAge p1 \
	isAdult:(lambda 
              CheckMoney p1 400 \
	            (lambda print "you can buy it") \
		    (lambda print "you don't have enough money to buy this"))\				
	isChild:(lambda print "you are not old enough to buy this") \
	isNotAlive:	(lambda print "you arent't even alive, c'mon man!")	
						

Full code:

struct lambda
(
	functionpointer,
	p1,p2,p3,p4,
	
	fn exec = 
	(
		if p4 != undefined then
			functionpointer p1 p2 p3 p4
		else if p3 != undefined then
			functionpointer p1 p2 p3
		else if p2 != undefined then
			functionpointer p1 p2
		else if p1 != undefined then
			functionpointer p1
		else
			functionpointer()
	)
)

fn Call fPointer =
(
	if classof fPointer == Lambda then
		fPointer.exec()
	else if classof fPointer == MAXScriptFunction then
		fPointer()
)


-- Test lambdas
fn CheckMoney person price hasMoney notEnoughMoney =
(
		if person.money >= price then 
			Call hasMoney
		else
			Call notEnoughMoney
			
)

fn CheckAge person isAdult: isChild: isNotAlive: =
(
		if person.age > 18 then 
			Call isAdult
		else if person.age > 0 then
			Call isChild
		else
			Call isNotAlive
				
)

fn PrintGreeting greeting person = (print (greeting + " " +person.name))

struct Person  (name, age , money)

	
p1 = Person "peter" 30 200

-- test calls some with 1 parameter and some with 2 parameter
CheckAge p1 \
	isNotAlive:	(lambda print "you arent't even alive, c'mon man!")\	
	isAdult:		(lambda PrintGreeting "welcome" p1)\				
	isChild:		(lambda print "is child")	
	
-- test lambda inside of lambda
CheckAge p1 \
	isAdult:(lambda CheckMoney p1 400 \
		(lambda print "you can buy it") \
		(lambda print "you don't have enough money to buy this"))\				
	isChild:(lambda print "you are not old enough to buy this") \
	isNotAlive:	(lambda print "you arent't even alive, c'mon man!")	
						

why is this ‘complexity’?

maxscript has well done ‘function’ passing mechanics…

fn average method a b power: = (method a b power:power)

fn linear a b = (a+b)/2.0
fn square a b = sqrt(a*a + b*b)
fn powered a b power:4 = pow (pow a power + pow b power) (1.0/power)

/*
average linear 2 4
average square 2 4
average powered 2 4 power:3
*/

to allow a function in maxscript to call another function for which it doesn’t
know its parameters

your average can just execute methods that takes two parameters. So you restrict what kind of function gets executed next.

can you pass an array of arguments?

Then I can just execute functions that take one array as argument.
Also I don’t think that solution will be more readable than my last solution.

I want to achieve that function ‘A’ calls function ‘B’ without knowing anything about function ‘B’.

edit: the goal is to get loose coupling

No, just an action, not the agruments.

My C# example from above:

public void main ()
{
   var shoppingcarditems = new List<string>();
   shoppingcarditem.Add("Apple");
   shoppingcarditem.Add("Orange");

   CheckAge(person, 
      onAdult: () => Checkout(person, shoppingcarditems)
      onChild () => PrintNotAllowedError() )
}


public void CheckAge(Person p, Action onAdult, Action onChild)
{
   if(p.Age > 18)
      onAdult();
   else 
      onChild();
}

CheckAge calls Checkout without knowing that it also gets passed shoppingcarditems into it from outside ( here the main function). Only the main function knows the Checkout function. The CheckAge function doens’t know other functions.

fn stringUnion method data &out: = 
(
	out = method data 
)

fn easyadd data = 
(
	s = ""
	for d in data do s += d
	s	
)
fn camelcase data = 
(
	s = ""
	for d in data do 
	(
		d = tolower d
		d[1] = toupper d[1]
		s += d
	)
	s
)

/*

stringUnion easyadd #("dogs", "and", "cats", "are", "not", "friends") out:&s0
stringUnion camelcase #("dogs", "and", "cats", "are", "not", "friends") out:&s1

s0
s1


*/

struct Job1
(
	data, 
	result,
	fn action = (result = (data[1] + data[2]))
)
struct Job2
(
	data, 
	result,
	fn action = (result = (data[1] as string + " + " + data[2] as string + " = " + (data[1] + data[2]) as string))
)

fn doAJob job = 
(
	job.action()
	ok
)

j1 = Job1 data:#(1,4)
doAJob j1
j1.result

j2 = Job2 data:#(1,4)
doAJob j2
j2.result

fn doAJobExt job data: = 
(
	if data != unsupplied do job.data = data 
	job.action()
	ok
)

struct Job3
(
	data, 
	result,
	fn action = 
	(
		act = if data[2] >= 0 then " + " else " - "  
		result = (data[1] as string + act + (abs data[2]) as string + " = " + (data[1] + data[2]) as string)
	)
)

j3 = Job3 data:#(0,0)
doAJobExt j3
j3.result
doAJobExt j3 data:#(1.3, -0.8)
j3.result