[Closed] Just quickly – a q on spinners

Hi,

Here’s something to get you started:

rollout ro_test "" 
(
	spinner sp1 "sp1"
	spinner sp2 "sp2"
	spinner sp3 "sp3"
	spinner sp4 "sp4"
	
	
	fn getSpiinerValues =
	(
		for c in ro_test.controls where isKindOf c spinnerControl collect c.value
	)
)
createDialog ro_test
ro_test.getSpiinerValues()

hOpe this helps,
o

Bloomin heck – where on earth would I have had to search for that in the Help docs?

I’ll test this out today and see what I get.

Also, as I understand it I can’t create spinners on the fly? For example, a user selects the amount of spinners he/she wants, and then these spinners are created there and then on the same rollout?

Anyway, I’ll get back to say if this works or not…

It can be done but’s it’s not pretty You have to build your interface in a large string with a for loop and execute the UI string when done, that way you can update and dynamicly change UI’s like the light lister, same principle. Maybe with dotnet there’s more control, but I wouldn’t no, unfortunatly.

-Johan

Bedankt Johan – I haven’t looked into dotNet at all with MSX (only been learning this past month), but I have done some VB and VB.net stuff so perhaps they’re nearly the same: I might look into it, and I see there’s a sticky on the subject anyway…
As for constructing lengthy strings – I’ll be fine for now!!

ofer_z – thanks, the code, once modified for my purposes, worked perfectly: here’s what I’m using for any other guys who might need it:

arrL = #() 
i = 1
for spn in ro_CustomLinks.controls where isKindOf spn spinnerControl do
(
	 if spn.value != 0 then arrL[i] = spn.value
	 i += 1
)

How does MXS run through the spinners though? i.e. in what order does the loop run through the spinners? Top to bottom (i.e. positional)?

I printed out the numbers in the array, and the loop seems to run through the spinners are they are in the code – i.e. the first value of the array is the value of the first spinner constructed in the code. However, when I try to delete the first three values of my array, it actually deletes the first, third and fourth values.

So, after creating the array using the code I gave above, I run this code:

for i = 1 to arrL.count do 
(
	 str = "Link" + i as string + " = " + arrL[i] as string
	 Print str
) 

Which gives me the order I expect.
Then I do this:

deleteItem arrL 1 
deleteItem arrL 2
deleteItem arrL 3
 
for i = 1 to arrL.count do 
(
	 str = "Link" + i as string + " = " + arrL[i] as string
	 Print str
) 

and it seems to delete the first, third and fourth values??

Any ideas? It might be blatantly obvious, so I apologise if it is!!

EDIT
Whoops, that’ll teach me to run my mouth – of course it’s obvious. The first time I run deleteItem the array decreases in size, thus

 deleteItem arrL 2

actually deletes the second item of the NEW array, and so on.

Idiot!! 😮

Anyway, many thanks guys for your help!!

arrL = #()
i = 1
for spn in ro_CustomLinks.controls where isKindOf spn spinnerControl do
(
if spn.value != 0 then arrL[i] = spn.value
i += 1
)

The following line does the above, and if you’re like me, I’m always looking for ways to make things faster.

  arrL = for spn in ro_CustomLinks.controls where isKindOf spn spinnerControl collect spn.value

How does MXS run through the spinners though? i.e. in what order does the loop run through the spinners? Top to bottom (i.e. positional)?

It loops through them in the order they are created.

Which gives me the order I expect.
Then I do this:
Code:
[left]
deleteItem arrL 1
deleteItem arrL 2
deleteItem arrL 3

for i = 1 to arrL.count do
(
str = “Link” + i as string + ” = ” + arrL[i] as string
Print str
) [/left]

and it seems to delete the first, third and fourth values??

It is obvious actually. Put a “print arrL” in between each deleteItem and you’ll see. I’ll illustrate.

arrL contains

[1]: 10
 [2]: 20
 [3]: 30
 [4]: 40
 [5]: 50
 

now you run the line deleteItem arrL 1 (which deletes the first index)

now arrL contains:

[1]: 20
 [2]: 30
 [3]: 40
 [4]: 50
 

now you run the line deleteItem arrL 2 so it deletes the second index of the array containing (30)

now arrL contains:

[1]: 20
 [2]: 40
 [3]: 50
 

As you can see the indexes change dynamically…get it?

-Colin

That’s what I wrote in the edit to my post!! Thanks though!!

And yeah, I prefer quicker methods of doing the same things, so I’ll try your suggestion.

Cheers
Tim

using a for loop with the collect keyword stores the value of what you collect in the variable you assign. It’s amazing, some other handy uses might be

-- This will build an array of the bitmaps in your scene where the files exist (ie. not missing bitmaps)
FoundBitmapsInScene = for b in (getClassInstances BitmapTexture) where (doesFileExist b.filename) collect b

perhaps you might need the not found bitmaps in the scene

-- This will collect missing bitmaps in the scene and store them in the array MissingBitmaps
MissingBitmaps = for b in (getClassInstances BitmapTexture) where not(doesFileExist b.filename) collect b

Just some cool uses for a great tool!

-Colin

Cheers everyone for your help – it’s all working perfectly!!

I have some more issues but I’ll start up a new thread as it’s slightly OT…

Cheers again
Tim