[Closed] Image display with dotNet?

I was going to ask “what’s wrong with display <bitmap>?” But I see you want it displayed in a rollout as well.

The real question is, can DotNet do this out of the box or not…

Now, there is a “PictureBox” control in “System.Windows.Forms” that MIGHT work, how much control you would get is another issue…

As I read it, it has a “Load(String)” method which “sets the ImageLocation to the specified URL and displays the image indicated”.

Now, unfourtantly, support for magnification (and scrollbars) may not be avaliable out of the box for this control, but you could “fake” some of the magnification yourself…But more about that later…

Scrolling could be achieved by placing the picture box inside a ScrollableControl…this is a little more complex, because you are now responsible for the layout (position and size) of the control…

But, basically, you would do something like myScrollableControl.controls.add myPictureBox

As for the magnification…there MIGHT be a way to do use the PictureBox itself…if that fails, you might need to convert the image into a pixel array and scale it yourself

But, PictureBox has a method “Scale(SizeF)”

Now SizeF has a number of cool properties, Height and Width been the most important, but Add(…) and Subtract(…) also look interesting…

As I understand the docs, Height and Width are a “factor” of the original size, that would mean that 1.0 is normal, 0.5 is half and 2.0 is double, but you will need to play around with these values to be sure…

NONE OF THIS HAS BEEN TESTED AND IS PURLY SPECULITVE…

Shane

MAXScript bitmap value or .NET bitmap value ?
In fact it’s better for speed to draw the bitmap .NET value in the paint event handler.

EDIT:

Here is my code for zooming without a scroll control:

(
	local uiDotNetPictureBoxZoomRollout
	local uiDotNetPictureBoxRCmenu
	
	local sRolloutTitle = ".NET PictureBox Zoom"
	local zoomFactor = 2.0
	
	local bmpWidth = 320
	local bmpHeight = 240
	local bmpDisplayed = dotNetObject "System.Drawing.Bitmap" "image.bmp"
	local bmpRectangle = dotNetObject "System.Drawing.Rectangle" 0 0 bmpWidth bmpHeight
	
	rcmenu uiDotNetPictureBoxRCmenu
	(
		subMenu "Zoom"
		(
			menuItem uiZoom100 "100"
			menuItem uiZoom200 "200"
			menuItem uiZoom300 "300"
			menuItem uiZoom400 "400"
			menuItem uiZoom500 "500"
		)
		
		on uiZoom100 picked do
		(
			zoomFactor = 1.0
			uiDotNetPictureBoxZoomRollout.updateZoom()
		)
		
		on uiZoom200 picked do
		(
			zoomFactor = 2.0
			uiDotNetPictureBoxZoomRollout.updateZoom()
		)
		
		on uiZoom300 picked  do
		(
			zoomFactor = 3.0
			uiDotNetPictureBoxZoomRollout.updateZoom()
		)
		
		on uiZoom400 picked do
		(
			zoomFactor = 4.0
			uiDotNetPictureBoxZoomRollout.updateZoom()
		)
		
		on uiZoom500 picked do
		(
			zoomFactor = 5.0
			uiDotNetPictureBoxZoomRollout.updateZoom()
		)
	)
	registerRightClickMenu uiDotNetPictureBoxRCmenu
	
	rollout uiDotNetPictureBoxZoomRollout sRolloutTitle
	(
		dotNetControl uiPictureBox "System.Windows.Forms.PictureBox" pos:[0,0] width:bmpWidth height:bmpHeight
		
		fn updateZoom =
		(
			zoomPercent = (zoomFactor * 100) as integer
			newWidth = bmpWidth*zoomFactor
			newHeight = bmpHeight*zoomFactor
			uiDotNetPictureBoxZoomRollout.Width = newWidth
			uiDotNetPictureBoxZoomRollout.Height = newHeight
			bmpRectangle.Width = newWidth
			bmpRectangle.Height = newHeight
			uiPictureBox.Width = newWidth
			uiPictureBox.Height = newHeight
			uiDotNetPictureBoxZoomRollout.Title = sRolloutTitle + " : " + (zoomPercent as string) + "%"
			uiPictureBox.Invalidate()
		)
		
		on uiPictureBox Paint senderArg paintEventArgs do
		(
			Graphics = paintEventArgs.Graphics
			Graphics.DrawImage bmpDisplayed bmpRectangle
		)
		
		on uiDotNetPictureBoxZoomRollout open do
		(
			uiDotNetPictureBoxZoomRollout.Title = sRolloutTitle + " : 100%"
		)
	)
		
	createdialog uiDotNetPictureBoxZoomRollout menu:uiDotNetPictureBoxRCmenu width:bmpWidth height:bmpHeight style:#(#style_titlebar, #style_border, #style_sysmenu)
	uiDotNetPictureBoxRCmenu.rolloutCtrl = uiDotNetPictureBoxZoomRollout 
)