[Closed] If And Or

What you could try at this point in learning is simply translate your sentence into maxscript word-by-word. Conditionals are surprisingly intuitive once you realise they work pretty much like in common language. Just replace stuff like “otherwise”/“but” with “else”.

So this…

If rows = 1 and columns = 1 then nothing happens. 
Otherwise, if rows = 1 and columns is > 1 or if rows is > 1 and columns = 1 then I want to create cylinder of radius 2.5 height 3, 
but if rows is > 1 and columns is > 1 then create a cylinder of radius 5.0 height 3

…becomes this:

if rows == 1 AND columns == 1 then 
(
	
)
else
(
	if (rows == 1 AND columns > 1) OR (rows > 1 AND columns == 1) then
	(
		Cylinder radius:2.5 height:3
	)
	else
	(
		if rows > 1 AND columns > 1 then Cylinder radius:5.0 height:3
	)
)

Having an empty block doing nothing isn’t the best style, so we can invert the statement “if rows and columns are both 1” into “if either rows or columns are more than 1”. Furthermore we can simplify the sentence: “if rows = 1 and columns > 1, or rows > 1 and columns == 1” to “if either row or column is equal to 1”, since we already checked if one of them is more than 1. And we don’t really need to check if both rows and columns are more than 1 in the else part, since we already ruled out that neither of them were equal to 1 in the if before it (we’re executing the else branch after all):

if rows > 1 OR columns > 1 then 
(
	if rows == 1 OR columns == 1 then
	(
		Cylinder radius:2.5 height:3
	)
	else
	(
		Cylinder radius:5.0 height:3
	)
)

An alternative is to use a case statement. But some people hate them:

case of
(
	((rows == 1 AND columns > 1) OR (rows > 1 AND columns == 1)): Cylinder radius:2.5 height:3
	(rows > 1 AND columns > 1): Cylinder radius:5.0 height:3
)

Ignore, misread question.

if (rows + columns > 2) do 
(
	radius = if (rows > 1 and columns > 1) then 5 else 2.5 
	cylinder radius:radius height:3
)

Thanks for the assist guys. Although I didn’t use that specific coding, I was able to modify my code to get it to work like I wanted it to by analyzing what you guys posted. I appreciate the help.

CF3D