[Closed] How to determine if a string is a keyword?

getEdgeVertex by itself is not a valid method, as you noted yourself. The full specification is Editable_Poly.getEdgeVertex and you can check for that easily by just asking for its class.

Editable_Poly.getEdgeVertex –> InterfaceFunction –> != undefined –> true

But

getEdgeVertex –> undefined

so without checking each possible struct and Function Publishing Interface for it, you cannot be sure.

If you suspect it could be in several FPS or structs, you could run through them and check, like

theFPS = "Editable_Poly"
 execute ("classof " + theFPS + "." + "getEdgeVertex") != undefined
 --> true

Now you could make theFPS a FOR loop variable, like

for theFPS in #("Editable_Poly","meshop","polyop") where \
   try(execute ("classof " + theFPS + "." + "getEdgeVertex") != undefined)catch(false) collect theFPS
 -->#("Editable_Poly")
 
 
 for theFPS in #("Editable_Poly","meshop","polyop") where \
   try(execute ("classof " + theFPS + "." + "getVert") != undefined)catch(false) collect theFPS
 -->#("meshop", "polyop")
 

Package this in a function, pass the string as argument and possibly use apropos to build an array of ALL possible structs and classes in MAXScript (!) and you could check that string against pretty much cases…

Here is a more expanded version:

(
local theClassesArray  = #()
	
fn initSearchFunction =
(
	local st = timestamp()
	theClassesArray  = #()
	local str = stringStream ""
	apropos "*" to:str
	seek str 0
	while not eof str do
	(
		local theLine = readLine str
		if matchPattern theLine pattern:"*Struct*" or matchPattern theLine pattern:"*Interface*" or matchPattern theLine pattern:"*MAXSuperClass*" or matchPattern theLine pattern:"*MAXClass*"  do
			append theClassesArray (filterString theLine " ")[1]
	)
	format "Initialized in % ms.
" (timestamp()-st)
	theClassesArray.count
)

fn isValidFunction theFunctionString =
(
	local st = timestamp()
	local theResult = for theFPS in theClassesArray where \
		try(execute ("classof " + theFPS + "." + theFunctionString) != undefined)catch(false) collect theFPS
	format "% Found in % ms.
" theResult.count (timestamp()-st)
	theResult
)

initSearchFunction()
isValidFunction "getVertex"

-->Initialized in 289 ms.
-->6 Found in 468 ms.
-->#("Editable_Poly", "EditablePolyMesh", "Edit_Normals", "EditNormals", "Edit_Poly", "EditPolyMod")
)