Me and and friend have just started to work on a little script for slicing a mesh with slice planes. We would like to make the user select the face(s), and the number of “slices” he wants, and then have the tool slice it up for him.
Our problem now is to find the max and min point of the current face selection. Unfortunately our code here, where obj is the given object, gives us the max and min of the entire selected object and not on the selection only … and therefore gives us a wrong slicing:
maxpoint = selection.max
minpoint = selection.min
total_height = abs (maxpoint.z – minpoint.z)
height_step_size = total_height / (num_heightsteps + 1)
[…]
for i = 1 to num_heightsteps do
(
obj.slice [0,0,1] [0, 0, start_heightpos + height_step_size*i] flaggedFacesOnly:true
)
Any ideas on how to get max and min for the selected polygon(s) instead of the entire object, in the first two lines in the above code example?
Thanks in advance,
Lars
Hi Lars, here is what you could do:
faceverts = polyop.getVertsUsingFace $.baseobject (polyop.getFaceSelection $.baseobject) –get vertices of selected faces
vertZ = for i in faceverts collect (polyop.getVert $.baseobject i node:$).z –collect all vertexpositions Z value into an array
vertZmax = amax vertZ –find the maximum value in the array wich is the highest position in the world Z-axis, the minimum value would be amin instead of amax
I hope it works out, cheers
CML
Wow, thank you so much Carl-mikael … it works beautifully, and I now did what you suggested for both x, y and z direction.
Thank you so much for your help
Lars
I have written a script that does something similar, except it will slice into even chunks (say 1m x 1m for example). You may find it will behave strangly when attempting to slice faces at odd angles… in which case you may need to create a matrix3 value for the face selection so the slice plane can align correctly to the face(s).
Hi Simon,
Oh cool – I did think that someone might have done a similar script before :). We are doing our script as a practice but also to get a tool for making a more detailed tesselation on special objects like the front faces of extruded text splines – to make them bend more smoothly. The things you mention sounds very much like what we are doing … we have spinners for x, y, z segment size and also keep them evenly spaced, so when the user changes one spinner then the others change acordinly to keep the 1×1 aspect. And yes, our script does makes some some strange slices at odd angles We did consider making the sliceplane align to the face(s) using the normal of the selection – but was not sure how to do it … I guess that we have to make some sort of “mean” between the normals of the selected faces?
Thank you for your input.
Lars
Hi!
You could probably do it with something like this:
-- Get selections and stuff
theObject = selection[1]
faceSel = polyop.GetFaceSelection theObject as array
faceVerts = polyop.getVertsUsingFace theObject faceSel
faceCenAvg = [0,0,0]
faceNormAvg = [0,0,0]
wUp = [0,0,1]
fn getAlignment =
(
--Get Average center point and normal of the faces
for f in faceSel do faceCenAvg += in coordsys theObject polyop.getFaceCenter theObject f
for f in faceSel do faceNormAvg += in coordsys theObject polyop.getFaceNormal theObject f
selCenter = faceCenAvg / faceSel.count
selNormal = faceNormAvg/faceSel.count
-- work out alignment (from the maxscript reference faq section "How do I align the UVW gizmo...")
rVec = normalize (cross wUp selNormal)
uVec = normalize (cross rVec selNormal)
selNormalMatrix = matrix3 rVec uVec selNormal selCenter
--some code from above to get the min and max points...
vertPositions = for v in faceVerts collect polyop.getVert theObject v
vertsX = for v in faceVerts collect in coordsys selNormalMatrix (polyop.getVert theObject v).x
vertsY = for v in faceVerts collect in coordsys selNormalMatrix (polyop.getVert theObject v).y
vertsZ = for v in faceVerts collect in coordsys selNormalMatrix (polyop.getVert theObject v).z
minmax = #([(amin vertsX), (amin vertsY), (amin vertsZ)], [(amax vertsX), (amax vertsY), (amax vertsZ)])
-- dump some objects so you can see whats going on...
p = plane width:(minmax[2].x-minmax[1].x) length:(minmax[2].y-minmax[1].y)
p.transform = selNormalMatrix*theObject.transform
bCenter = box name:"Center"
bMin = box name:"Min"
bMax = box name:"Max"
bCenter.pos = selCenter*theObject.transform
-- you can use the Matrix you worked out above as the coordsys, kinda like a user grid...
in coordsys selNormalMatrix bMin.pos = minmax[1]
in coordsys selNormalMatrix bMax.pos = minmax[2]
)
getAlignment()
Not perfect, but works for most situations… Hope it helps!
Wow thanks Simon for making and posting this function – and it works … those three test boxes are placed at center, max and min postions (facing “the normal” way), and the transformed plane is perfectly placed on the face that I select before running the script. I am currently studying your code to understand it better (I guess I need to brush up on my matematics regarding matrix aritmetics Thanks also for the detailed comments in the code – this helps a lot for the reading/understanding.
Lars