[Closed] Get property type

Keep in mind that this only works for values that actually exist.

E.g.

 $.modifiers[1]
 Displace:Displace
 getProperty meditmaterials[1] #diffuseMap
 undefined
 classOf (getProperty meditmaterials[1] #diffuseMap)
 UndefinedClass
 

So you can’t use that to dynamically create a mapButton as all the script tells you is that the value is undefined – not what the expected value would be.

Here’s an alternative:

 -- could change this to use by-reference parameters to deal with the two array results
 fn getProps obj = (
 	propString = stringStream ""
 	showproperties obj to:propString
 	propString = propString as string
 	propArray = filterString propString "
"
 	if (propArray.count == 0) then ( return #(#(),#()) )
 	propNamesArray = #(); propNamesArray[propArray.count] = undefined
 	propTypesArray = #(); propTypesArray[propArray.count] = undefined
 
 	for i = 1 to propArray.count do (
 		prop = propArray[i]
 		prop = filterString prop ":"
 		propNamesArray[i] = (subString (sfs.lib.strTrim (filterString prop[1] " ")[1]) 2 -1) as name
 		if (prop.count == 2) then ( propTypesArray[i] = sfs.lib.strTrim prop[2] )
 	)
 	#(propNamesArray,propTypesArray)
 )
 
 fn getPropType obj prop = (
 	props = getProps obj
 	propNames = props[1]
 	propTypes = props[2]
 	propIndex = findItem propNames prop
 	if (propIndex != 0) then ( propTypes[propIndex] )
 	else ( false )
 )
 getPropType $.modifiers[1] #map
 "texturemap"
 

Note that there is a special set of types of parameter values that end in ‘array’… these are of class ArrayParameter and basically work like an array and would have to be accessed as such to enumerate the actual parameters; this applies to the above script as well as Gravey’s method. Each ArrayParameter can only be an array with parameters of the same type, so the above code should tell you what type of data is in the array… e.g. texturemap, percent (float), float, etc.

Also note that some parameters may have spaces in them… it shouldn’t happen, but I’ve seen it happen in at least (older versions of?) DreamScape, parameter “.Pixel Sampler”. The space should be removed for proper access.

==================================================

Edit: just a .NET thingy that makes use of some of this… it doesn’t access the properties, so the ‘spaces in parameter names’ is not dealt with.

Just enter a target (standard script code… e.g ‘$’ or ‘$.material’, etc.) and it will make a nice tree item for that target with all of the parameter names, their values, their value types ( in parentheses for types derived with the above code, curly braces for classOf() ), and class hierarchy if it’s a maxwrapper. The tree branches out for any parameters that have subparameters as well as for ArrayParameters.

fn classGetHierarchy theClass = (
	local classHierarchy = #(theClass)
	while ((theClass = classOf theClass) != classHierarchy[1]) do (
		insertItem theClass classHierarchy 1
	)
	return classHierarchy
)

try(destroyDialog treeview_rollout)catch()
rollout treeview_rollout "Properties Tree" width:512 height:540 (
	dotNetControl tv "TreeView" width:500 height:500 align:#center
	edittext edt_targ "target" across:3
	button btn_add "add"
	button btn_clear "clear"

	fn getProps obj = (
		propString = stringStream ""
		showproperties obj to:propString
		propString = propString as string
		propArray = filterString propString "
"
		if (propArray.count == 0) then ( return #(#(),#()) )
		propNamesArray = #(); propNamesArray[propArray.count] = undefined
		propTypesArray = #(); propTypesArray[propArray.count] = undefined

		for i = 1 to propArray.count do (
			prop = propArray[i]
			prop = filterString prop ":"
			propNamesArray[i] = (subString (sfs.lib.strTrim (filterString prop[1] " ")[1]) 2 -1) as name
			if (prop.count == 2) then ( propTypesArray[i] = sfs.lib.strTrim prop[2] )
		)
		if (isKindOf obj node) then ( join propNamesArray (getPropNames node) )
		#(propNamesArray,propTypesArray)
	)

	fn clearTV = (
		tv.nodes.clear()
	)

	fn hasProperties obj = (
			try (
				local props = getPropNames obj
				classOf props == Array
			)
			catch ( false )
	)
	fn addProps node obj i: = (
		local propData = getProps obj
		local propNames = propData[1]
		local propTypes = propData[2]
		for prop in propNames do (
			local propValue = getProperty obj prop
			local propValueStr
			if (classOf propValue == string) then  ( propValueStr = "\"" + propValue + "\"" )
			else if (classOf propValue == ArrayParameter) then ( propValueStr = "[arrayParameter]" )
			else ( propValueStr = propValue as string )
			local propType = undefined
			local propTypeStr = ""
--			if ((propValue == undefined) OR (classOf propValue == ArrayParameter)) then (
				local propIndex = findItem propNames prop
				local propType = if (propIndex == 0) then ( undefined ) else ( propTypes[propIndex] )
				if (propType == undefined) then (
					propType = (classOf propValue) as string
					propTypeStr = " {" + propType + "}"
				)
				else (
					propTypeStr = " (" + propType + ")"
				)
--			)
			local classHierarchy
			local classHierarchyStr = ""
			if (isKindOf propValue maxWrapper) then (
				classHierarchy = classGetHierarchy propValue
				if (classHierarchy.count >= 2) then (
					for i = (classHierarchy.count - 1) to 1 by -1 do (
						classHierarchyStr += classHierarchy[i] as string + (if (i > 1) then ( " > " ) else ( ""))
					)
				)
				else ( classHierarchyStr = classHierarchy[1] as string )
			)
			if (classHierarchyStr != "") then ( classHierarchyStr = " :: " + classHierarchyStr )
			newNode = node.nodes.add ((prop as string) + " = " + propValueStr + propTypeStr + classHierarchyStr)
			if (hasProperties propValue) then ( addProps newNode propValue )
			if (classOf propValue == ArrayParameter) then (
				propTypeStr = subString propTypeStr 1 ((findString propTypeStr "array") - 2) + ")"
				for i = 1 to propValue.count do (
					propValueStr = propValue[i] as string

					-- horrible code copy/paste that should be a function
					local classHierarchy
					local classHierarchyStr = ""
					if (isKindOf propValue[i] maxWrapper) then (
						classHierarchy = classGetHierarchy propValue[i]
						if (classHierarchy.count >= 2) then (
							for i = (classHierarchy.count - 1) to 1 by -1 do (
								classHierarchyStr += classHierarchy[i] as string + (if (i > 1) then ( " > " ) else ( ""))
							)
						)
						else ( classHierarchyStr = classHierarchy[1] as string )
					)
					if (classHierarchyStr != "") then ( classHierarchyStr = " :: " + classHierarchyStr )
					-- /horrible code copy/paste
			
					local apNode = newNode.nodes.add ((prop as string) + "[" + i as string + "] = " + propValueStr + propTypeStr + classHierarchyStr)
					if (hasProperties propValue[i]) then ( addProps apNode propValue[i] )
					-- apNode.Expand()
				)
			)
			-- newNode.Expand()
		)
	)
	on tv doubleClick arg do (
		hitNode = tv.GetNodeAt (dotNetObject "System.Drawing.Point" arg.x arg.y)
		if hitNode != undefined do ( print hitNode )
	)

	fn addInfo obj = (
		newNode = tv.nodes.add (obj as string)
		addProps newNode obj
		newNode.expand()
	)

	on btn_add pressed do (
--		addInfo (execute edt_targ.text)
		try (addInfo (execute edt_targ.text)); catch()
	)
	on btn_clear pressed do (
		clearTV()
	)
)
createDialog treeview_rollout

Any node you specify as a target is ‘special’ as it adds the common properties for ‘node’ (name, material, target, etc.) although it can’t derive the expected type automatically. So e.g. ‘target’ is “undefined {UndefinedClasS}” unless it actually has a target. Can’t do much about that one other than per-case code.