[Closed] Building a Directory Struct for dotNet TreeView

Hey Paul, was looking at this tutorial from yourself…

http://paulneale.com/tutorials/dotNet/treeView/dotNetTreeView.htm

and i’m trying to use the above code to make use the dotnet TreeView as a directory lister. Something like this… also from your website… top left

Well you don’t need structs, you just need a recursive function to run down the tree of directories and build the treeView nodes as they go.

Have you done recursive functions before?

Have you checked my custom treeview? It does what you want, http://forums.cgsociety.org/showthread.php?f=98&t=678302

wrote this before I refreshed and saw Artur’s response. Regardless this still might help:

try(destroyDialog theRollout)catch()
rollout theRollout "The Rollout" width:300
(
	local TreeNodeClass = dotnetclass "System.Windows.Forms.TreeNode"
	
	dotNetControl tv "system.windows.forms.treeView" height:200
	
	fn GetDirectoryTree dir =
	(
		flt = filterstring dir "\\"
		dirName = flt[flt.count]
		
		t = dotnetobject TreeNodeClass dirName
		t.Tag = dir -- assign the full path to the tag property
		
		subDirs = GetDirectories (dir+@"/*")
		subNodes = for d in subDirs collect GetDirectoryTree d
		t.Nodes.AddRange subNodes
		
		t
	)
	
	on theRollout open do
	(
		n = GetDirectoryTree (getDir #maxroot)
		tv.Nodes.Add n
	)
)
createDialog theRollout

Ah I see, well you can use the tab property of each treeView node to store the path for that directory. Then when accessing in that directory you can just refer to the treeView nodes .tab property.

A recursive function is needed to recurse all the directories from a parent down through all the children.

This will print all files and directory paths in Max to the listener.

fn recurseDirs root=
(
	files=getFiles (root+"*.*")
	for f in files do format "	File: %
" (fileNamefromPath f)
	
	dirs=getDirectories (root+"*")
	for d in dirs do 
	(
		format "Dir: %
" d
		recurseDirs d
	)
)
recurseDirs (getDir #maxRoot)

I think you mean tag with a G

the GetDirectoryTree function in my previous post does exactly this

Sorry “tag”

Cheers Gravey, that works just as I needed to.

Thanks for the explanation Paul, didn’t realise you could use tags like that.

Is there a way to expand the first node in the tree? I can use the tv.ExpandAll() to expand everything but I only want the first node expanded.

And one other small thing, can I get the recursive function (Gravey’s) to ignore certain folders, with say name “maps” from being included in the tree.