[Closed] Barycentric coordinates?

In case you’re working with an Editable Mesh, this should do it:

meshop.[b]getBaryCoords[/b] <Mesh mesh> <int faceIndex> <point3 pos>
[b]node[/b]:<node=unsupplied>

The barycentric coordinates of the specified point in the plane of the
specified face, relative to the face. If <[b]mesh[/b]> is a node,
or if <[b]mesh[/b]> is an Editable Mesh or a Mesh value and [b]node[/b]
is specified, the position is in the current coordinate system context.
If <[b]mesh[/b]> is an Editable Mesh or a Mesh value and [b]node[/b]
is not specified, the position is in the mesh's local coordinate system.

Cheers,
Martijn

Hey Martijn, thanks. I have already read up on that one but the thing is that the triangle is not a meshface so I need the mathematical solution for calclating it. I tried searching on the web too but I can’t fully understand the solutions I’ve found. I need a simple example explaining how it’s done.

cheers,
CML

Here is an example in MAXScript:

1. Create a Line shape in the form of triangle in the top viewport
2. Convert to Editable Mesh
3. Create a Dummy at the position of interest in the top viewport inside the triangle (it is in the same plane!)

   theMesh = $Line01         --this is the mesh triangle with just one face
   v1 = getVert theMesh 1  --get the 3 vertices in world space
   v2 = getVert theMesh 2  
   v3 = getVert theMesh 3
   p = $Dummy01.pos        --get the position of the dummy as the point to get the bary coords from
   
   vector1 = p - v1           --this is the vector from vertex 1 to the dummy
   vector2 = p - v2           --this is the vector from vertex 2 to the dummy
   vector3 = p - v3           --this is the vector from vertex 3 to the dummy
   
   
   --because the length of the cross product vector is equal to the area of the parallelogram
   --defined by the two operands, half of it is the area of the triangle!
   area1 = (length (cross vector2 vector3))/2  --this is the area of the first sub-triangle
   area2 = (length (cross vector1 vector3))/2  --this is the area of the second sub-triangle
   area3 = (length (cross vector1 vector2))/2  --this is the area of the third sub-triangle
   
   fullArea = area1 + area2 + area3 --this is the full area of the triangle
   
   b1 = area1 / fullArea  --this is the proportion of the first triangle vs. the full triangle
   b2 = area2 / fullArea  --this is the proportion of the second triangle vs. the full triangle
   b3 = area3 / fullArea  --this is the proportion of the third triangle vs. the full triangle
   
   baryCoords = [b1, b2, b3]  --Behold! Hand-made Barycentric coordinates!!!
   baryfrommesh = meshop.getBaryCoords theMesh 1 p --compare to the MAXScript result...

Oh man I can’t thank you enough for this, I’ve banged my head at this for some time now. There is something more though…if the point lies outside the triangle you can still get the coordinates with meshop.getBaryCoords, but with the example it doesn’t work in that case. What can I do?

Thanks!
CML

Sweet! Now it’s working great. Thanks a lot for taking the time Bobo.

edit: one small optimization would be to loose the acos part since it should be enough to dot the vectors, right?

CML