[Closed] Aligning objects local Bounding box to a facenormal?

Don’t think there is a better solution – when I had to do it, I did just that (but it was more complicated, as it involved growing crystals where I had to find out what the main direction of the crystal was based on edge lenghts and perform the orientation automatically).
Create a matrix from normal with position equal to the current position of the object, transform by the inverse of it to get the object aligned to the world origin, reset, then transform back.

Here is a simple example using the first normal:

fn AlignBBoxToFirstNormal theObject = 
  (
  theCurrentTM = theObject.transform --this is the current transformation
  theMesh = snapshotasmesh theObject --get the world space TriMesh
  theTM = matrixFromNormal (getFaceNormal theMesh 1) --build a matrix from normal
  delete theMesh --delete the TriMesh from memory
   theTM.row4 = theCurrentTM.row4 --set the position of the new matrix to the old pos
  theObject.transform *= inverse theTM --transform out of world space 
  resetXForm theObject --reset the XForm
  convertToMesh theObject --collapse the stack
  theObject.transform = theTM --transform back into world space
  )

To test this, I created a plane, moved and rotated it freely and reset the XForm myself to get a “bad” bbox. Then called the function and got a flat bbox.

This method does not give you the perfect orientation of the X and Y axes though, only the Z is aligned to make the bbox as flat as possible assuming all faces are coplanar to the first normal. In a better version, you could figure out the longest edge or something like that and use that direction as an X axis and build the Y as the cross-product of the normal and the X, then build your own matrix3 value out of the three vectors and the current position.
Also, if the normals are slightly different, you could average all normals of all faces and align the Z to the result instead of taking just one as I did above.
But the basics are the same…

In my test with the plane, I modified the function to use the first edge of the first face as the Y axis:

fn AlignBBoxToFirstNormal theObject = (
 theCurrentTM = theObject.transform
 theMesh = snapshotasmesh theObject
 theZ = normalize (getFaceNormal theMesh 1)
 theFace = getFace theMesh 1
 theY = normalize ((getVert theMesh theFace.y)-(getVert theMesh theFace.x))
 theX = normalize (cross theY theZ)
 theTM = matrix3 theX theY theZ theCurrentTM.row4
 theObject.transform *= inverse theTM
 resetXForm theObject
 convertToMesh theObject
 theObject.transform = theTM
  )

Even better, you could allow the user to SELECT the edge to be used as the Y axis and build the matrix out of that, but it would be only semi-automatic then as it would require a user for edge selection…